Re: [NMusers] simulation problem

Hi Jing:

I tried your model and I think there are few minor corrections needed in
your model as shown below:

$DES
       C1 = A(1)/V1
DADT(1) = - C1*VM/(KM+C1)- (K12+K13+K14)*A(1)+K21*A(2)+K31*A(3)
       DADT(2) = K12*A(1) - K21*A(2)
       DADT(3) = K13*A(1) - K31*A(3)
       DADT(4) = K14*A(1) - K40*A(4)

I used C1 instead of A(1) in the first term of DADT(1).
I replaced K13*A(2) with K13*A(1) in the first term of DADT(3). Hope
this will work for you.

Best regards,
Sam Liao
Pharmax Research
> Dear users,
>
> I am doing a PK-PD simulation with effect compartment model to simulate
> the drug concentrations and PD biomarker concentrations simultaneously
> under different dose levels. The drug is administered as intravenous
> infusion. The PK is a three-compartment model with Michaelis-Menton
> elimination from the central compartment, and the PD is the stimulatory
> Emax model.
>
> After simulation, I found there is something wrong with the simulated
> drug and biomarker concentrations. In general, the simulated drug
> concentration-time profiles look good, but there is not always a
> consistent increase in the concentration (e.g., Cmax at the end of
> infusion) with the increase of the dose. The simulated biomarker
> concentrations exhibit an erratic profile. I would very much appreciate
> if someone can point out where I am doing wrong in this PK-PD
> simulation.
>
> The code is as followings:
>
> $PROB SIMULATE PK AND PD DATA TO SIMPLE PK-LINK-PD MODEL
> $DATA DRUG_SIM_3.csv IGNORE=@
> $INPUT ID AMT=DOSE RATE TIME DV MDV EVID SEX BSA FLAG CMT
> $SUBROUTINES ADVAN6 TOL=5
> $MODEL NCOMP = 4
> COMP=(CENTRAL,DEFDOSE,DEFOBS)
> COMP=(PERIPH1)
> COMP=(PERIPH2)
> COMP=(EFFECT)
> $PK
> VM = 122*(1+0.502*(2-SEX))*EXP(ETA(1))
> KM = 111*EXP(ETA(7))
> V1 = 8.15*(BSA/1.8)**0.69*EXP(ETA(2))
> V2 = 7.54*EXP(ETA(3))
> V3 = 25.5*EXP(ETA(4))
> Q2 = 5.01*EXP(ETA(5))
> Q3 = 2.74*EXP(ETA(6))
> K12 = Q2/V1
> K21 = Q2/V2
> K13 = Q3/V1
> K31 = Q3/V3
> S1 = V1
> ;EFF COMP
> K14 = .001*K12
> K40 = THETA(1)*EXP(ETA(8))
> S4 = S1*K14/K40
> EMAX = THETA(2)*EXP(ETA(9))
> C50 = THETA(3)*EXP(ETA(10))
> BSL = THETA(4)*EXP(ETA(11))
> ;OBS = XDV
> $DES
> C1 = A(1)/V1
> DADT(1) = - A(1)*VM/(KM+C1)- (K12+K13+K14)*A(1)+K21*A(2)+K31*A(3)
> DADT(2) = K12*A(1) - K21*A(2)
> DADT(3) = K13*A(2) - K31*A(3)
> DADT(4) = K14*A(1) - K40*A(4)
>
> $ERROR
> TMPC=0
> IF(CMT.EQ.1) TMPC=1
> TMPE=1-TMPC
> DEL = 0
> IF(F.EQ.0) DEL = .000001
> IF (TMPC.EQ.1) IPRED = LOG(F + DEL)
> IF (TMPC.EQ.1) W=.269
> IF (TMPE.EQ.1) IPRED = LOG(BSL*(1+EMAX*F/(C50+F)))
> IF (TMPE.EQ.1) W = THETA(5)
> IRES = DV-IPRED
> IWRES = IRES/W
> Y = IPRED+ERR(1)*W
>
> $THETA .321 ;1 K40
> $THETA 2.75 ; 2 EMAX
> $THETA 659 ; 3 C50
> $THETA 46.2 ;4 BL
> $THETA .267 ;5 W
> $OMEGA 0 FIX ;1 VM
> $OMEGA 0 FIX ;2 V1
> $OMEGA 0 FIX ;3 V2
> $OMEGA 0 FIX ;4 V3
> $OMEGA 0 FIX ;5 Q2
> $OMEGA 0 FIX ;6 Q3
> $OMEGA 0 FIX ;7 KM
> $OMEGA 0 FIX ;8 K40
> $OMEGA 0 FIX ;9 EMAX
> $OMEGA 0 FIX ;10 C50
> $OMEGA 0 FIX ;11 BSL
> $SIGMA 1 FIX
> $SIMULATION (9215690) ;seed 1-7 digits
> $TAB ID AMT TIME DV SEX BSA CMT ONEHEADER NOPRINT FILE=mytab14
>
> The datafile for the first three subjects is as the following:
>
> #ID AMT RATE TIME DV MDV EVID SEX BSA FLAG CMT
> 1 354 1074 0 . 1 1 1 1.8 0 1
> 1 0 0 0 . 0 0 1 1.8 3 4
> 1 0 0 0.33 . 0 0 1 1.8 2 1
> 1 0 0 0.33 . 0 0 1 1.8 3 4
> 1 0 0 1 . 0 0 1 1.8 2 1
> 1 0 0 1 . 0 0 1 1.8 3 4
> 1 0 0 2 . 0 0 1 1.8 2 1
> 1 0 0 2 . 0 0 1 1.8 3 4
> 1 0 0 4 . 0 0 1 1.8 2 1
> 1 0 0 4 . 0 0 1 1.8 3 4
> 1 0 0 8 . 0 0 1 1.8 2 1
> 1 0 0 8 . 0 0 1 1.8 3 4
> 1 0 0 12 . 0 0 1 1.8 2 1
> 1 0 0 12 . 0 0 1 1.8 3 4
> 1 0 0 24 . 0 0 1 1.8 2 1
> 1 0 0 24 . 0 0 1 1.8 3 4
> 1 0 0 48 . 0 0 1 1.8 2 1
> 1 0 0 48 . 0 0 1 1.8 3 4
> 2 709
> 2149 0 . 1 1 1 1.8 0 1
> 2 0 0 0 . 0 0 1 1.8 3 4
> 2 0 0 0.33 . 0 0 1 1.8 2 1
> 2 0 0 0.33 . 0 0 1 1.8 3 4
> 2 0 0 1 . 0 0 1 1.8 2 1
> 2 0 0 1 . 0 0 1 1.8 3 4
> 2 0 0 2 . 0 0 1 1.8 2 1
> 2 0 0 2 . 0 0 1 1.8 3 4
> 2 0 0 4 . 0 0 1 1.8 2 1
> 2 0 0 4 . 0 0 1 1.8 3 4
> 2 0 0 8 . 0 0 1 1.8 2 1
> 2 0 0 8 . 0 0 1 1.8 3 4
> 2 0 0 12 . 0 0 1 1.8 2 1
> 2 0 0 12 . 0 0 1 1.8 3 4
> 2 0 0 24 . 0 0 1 1.8 2 1
> 2 0 0 24 . 0 0 1 1.8 3 4
> 2 0 0 48 . 0 0 1 1.8 2 1
> 2 0 0 48 . 0 0 1 1.8 3 4
> 3 1418 4298 0 . 1 1 1 1.8 0 1
> 3 0 0 0 . 0 0 1 1.8 3 4
> 3 0 0 0.33 . 0 0 1 1.8 2 1
> 3 0 0 0.33 . 0 0 1 1.8 3 4
> 3 0 0 1 . 0 0 1 1.8 2 1
> 3 0 0 1 . 0 0 1 1.8 3 4
> 3 0 0 2 . 0 0 1 1.8 2 1
> 3 0 0 2 . 0 0 1 1.8 3 4
> 3 0 0 4 . 0 0 1 1.8 2 1
> 3 0 0 4 . 0 0 1 1.8 3 4
> 3 0 0 8 . 0 0 1 1.8 2 1
> 3 0 0 8 . 0 0 1 1.8 3 4
> 3 0 0 12 . 0 0 1 1.8 2 1
> 3 0 0 12 . 0 0 1 1.8 3 4
> 3 0 0 24 . 0 0 1 1.8 2 1
> 3 0 0 24 . 0 0 1 1.8 3 4
> 3 0 0 48 . 0 0 1 1.8 2 1
> 3 0 0 48 . 0 0 1 1.8 3 4
>
> Thanks in advance!
>
> Jing
>
>
>
>