RE: [NMusers] Modeling enantiomeric and racemic concentrations simultaneously

Dear Rasmus,
 
Below you will find a suggestion for how this could be coded in NONMEM. =
To simplify the code I have assumed i.v bolus dosing and one-compartment =
models for each enantiomer and no interconversion between the two =
enantiomers. I also assume that you know how much of each enantiomer the =
administered dose contains and that you in the data file specify this as =
two separate doses into separate compartments. If the ratio of the two =
enantiomers in the dose is not well defined a slightly different =
approach needs to be used. In case of any non-linear processes ADVAN 6 =
with defined differential equations ($DES) needs to be used instead of =
the suggested ADVAN5 (general linear model). Good luck!
 
; =
-------------------------------------------------------------------------=
--------------------------------------
$PROBLEM Enantiomers and racemate
$INPUT ID TIME AMT DV EVID CMT FLAG
; DV = S-enantiomer concentration => FLAG = 1
; DV = R-enantiomer concentration => FALG = 2
; DV = Racemic concentration => FLAG = 3
; LOG transformed DV variable
$DATA file.csv IGNORE=@
$SUBROUTINE ADVAN5 TRANS1
 
$MODEL
COMP = (1_CENT_S) ; Obs S-enantiomer
COMP = (2_CENT_R) ; Obs R-enantiomer
 
$PK
CLS = THETA(1) * EXP(ETA(1))
VCS = THETA(2) * EXP(ETA(2))
 
CLR = THETA(3) * EXP(ETA(3))
VCR = THETA(4) * EXP(ETA(4))
 
BIAS = 1 + THETA(5)
; Posible BIAS between non-enantiomer specific and specific
; analysis method. Drop this parameter if it is not needed.
 
K10 = CLS/VCS
K20 = CLR/VCR
 
$ERROR
CS = A(1)/VCS ; Plasma concentration of =
S-enantiomer
CR = A(2)/VCR ; Plasma concentration of =
R-enantiomer
CSR = (CS + CR) * BIAS ; Racemic plasma concentration
 
IF(FLAG.EQ.1) THEN
  IPRED = LOG(CS)
  W = THETA(6)
  IRES = DV-IPRED
  IWRES = IRES/W
  Y = IPRED+W*EPS(1)
ENDIF
IF(FLAG.EQ.2) THEN
  IPRED = LOG(CR)
  W = THETA(7)
  IRES = DV-IPRED
  IWRES = IRES/W
  Y = IPRED+W*EPS(2)
ENDIF
IF(FLAG.EQ.3) THEN
  IPRED = LOG(CSR)
  W = THETA(8)
  IRES = DV-IPRED
  IWRES = IRES/W
  Y = IPRED+W*EPS(3)
ENDIF
 
$ESTIMATION POSTHOC MAXEVAL=9999 METHOD=1
; =
-------------------------------------------------------------------------=
--------------------------------------
 
 
Kind regards,

Martin Bergstrand, MSc, PhD student
-----------------------------------------------
Division of Pharmacokinetics and Drug Therapy
Department of Pharmaceutical Biosciences
Uppsala University
-----------------------------------------------
P.O. Box 591
SE-751 24 Uppsala
Sweden
-----------------------------------------------
martin.bergstrand_at_farmbio.uu.se
-----------------------------------------------
Work: +46 18 471 4639
Mobile: +46 709 994 396
Fax: +46 18 471 4003
 
 
 
 
-----Original Message-----
From: owner-nmusers_at_globomaxnm.com =
[mailto:owner-nmusers_at_globomaxnm.com]On Behalf Of Rasmus Jansson
Sent: 18 juni 2007 15:26
To: nmusers_at_globomaxnm.com
Subject: [NMusers] Modeling enantiomeric and racemic concentrations =
simultaneously


Dear all,
I have conducted a pharmacokinetic study in rat and I have a question =
about how to model enantiomeric and racemic concentrations =
simultaneously.
The study design was as follows:
Sparse data (2 - 3 plasma samples, n=10 rats) was collected for the =
two enantiomers, and rich data for the racemate (10-15 plasma samples, =
n=4 rats) following oral administration.
I would like to build an individual model for each enantiomer and use =
the racemic data to stabilize the sparse data I have on the enantiomers. =
Do you have any suggestions how this could be done and how such a =
control-file should be written?
 
Kind regards,
Rasmus Jansson
_____________________________________________
Rasmus Jansson
Unit for Pharmacokinetics and Drug Metabolism
Göteborg University
P.O.Box 431, SE-405 30 Göteborg
Sweden
Phone: +46(0)31 786 3240
Fax: +46 (0)31 786 3284
 

Received on Wed Jul 04 2007 - 06:14:46 EDT