RE: [NMusers] Indirect response model

Hi Nishit,

 

Isn't F1 a reserved parameter in the PK block? I would try the
following code.

$PK
   KFOR = THETA(1)
   KCL = THETA(2)*EXP(ETA(1))
   IC50 = THETA(3)
   IMAX = THETA(4)
   BASE = KFOR/KCL
   COEF = IMAX*COP/(IC50+COP)

$DES
   DADT(1) = BASE*KCL-KCL*(1-COEF)*A(1)

 

Regards,

Sunny



________________________________

From: owner-nmusers_at_globomaxnm.com [mailto:owner-nmusers_at_globomaxnm.com]
On Behalf Of Modi, Nishit [ALZUS]
Sent: Tuesday, May 15, 2007 12:21 PM
To: nonmem_at_optonline.net
Cc: nmusers_at_globomaxnm.com
Subject: [NMusers] Indirect response model

 

I am conducting a sequential pharmacokinetic-pharmacodynamic model. The
pharmacokinetic fits look good and I was using an indirect response
model. The PD model is that the drug inhibits clearance of the analyte
(PD response), thus one expects that the response increases with
increasing drug (Model II). There is a baseline measured (=Kfor/Kcl)
and a dummy dose=1 unit given. It seems despite trying various
permutations of the model, eta1 seems to be very small and no covariance
step is conducted. The model and data for the first 3 subjects are
reproducted below. Any assistance would be appreciated. Note that
since conc (COP) are read in, the model only requires a single
differential equation. Any insight would be appreciated.

Nishit

$PROBLEM PD - ADVAN6
$DATA C:\PDDATA.CSV
$INPUT ID TIME DV AMT=DOSE COP MDV
; data are subject ID, Time, DV=PD response, Amt (dummy dose of 1
inserted), COP=plasma conc which drive PD model, MDV
$SUBROUTINES ADVAN6 TOL=6
$MODEL
   COMP=(EFFECT, DEFDOSE, DEFOBS)
  
$PK
   KFOR = THETA(1)
   KCL = THETA(2)*EXP(ETA(1))
   IC50 = THETA(3)
   IMAX = THETA(4)
   F1 = KFOR/KCL
   COEF = IMAX*COP/(IC50+COP)

$DES
   DADT(1) = KFOR-KCL*(1-COEF)*A(1)
$ERROR
     W = F
     Y = F*EXP(ERR(1))
     IPRED = F
     IRES = DV-IPRED
     IF (W.LE.0.) W=1
     IWRES = IRES/W

$THETA (0,0.3)
$THETA (0, 0.003)
$THETA (0,10)
$THETA (0, 0.3, 1)

$OMEGA 0.01
$SIGMA 0.5

$ESTIMATION METHOD=1 MAXEVAL=5000 PRINT=20
$COVR
$TABLE ID TIME PRED IPRED IRES KFOR KCL IC50 IMAX
    NOPRINT ONEHEADER
    FILE=C:\PD.TAB

1001 0 . 1 0 1
1001 0 98.3 . 0 0
1001 168 90.6 . 122.44 0
1001 840 92.8 . 183.69 0
1002 0 . 1 0 1
1002 0 105.1 . 0 0
1002 840 88.5 . 61.253 0
1002 842 106.7 . 106.8 0
1002 844 122.1 . 116.4 0
1002 1848 129.1 . 121.46 0
1002 1850 160.4 . 212.63 0
1002 1852 157.1 . 231.89 0
1101 0 . 1 0 1
1101 0 68.1 . 0 0
1101 840 88.1 . 0.13884 0
1101 842 105.5 . 0.12987 0
1101 844 108.8 . 0.12147 0
1101 1848 113.3 . 227.79 0
1101 1850 62.6 . 379.54 0
1101 1852 138.7 . 412.18 0

----------------------------------------------------------------------
LEGAL NOTICE
Unless expressly stated otherwise, this message is confidential and may be =
privileged. It is intended for the addressee(s) only. Access to this E-ma=
il by anyone else is unauthorized. If you are not an addressee, any disclo=
sure or copying of the contents of this E-mail or any action taken (or not =
taken) in reliance on it is unauthorized and may be unlawful. If you are n=
ot an addressee, please inform the sender immediately.
Received on Tue May 15 2007 - 13:36:15 EDT