Antwort: [NMusers] PK/PD models to describe anti-ancer drug effect on the tumor volume

Dear Patrick,

the Simeoni model works well:
Simeoni M, Magni P, Cammia C, De Nicolao G, Croci V, Pesenti E, Germani M, =

Poggesi I, Rocchetti M.
Predictive pharmacokinetic-pharmacodynamic modeling of tumor growth
kinetics in xenograft models after administration of anticancer agents.
Cancer Res. 2004 Feb 1;64(3):1094-101.

I've attached a code using this model below. My code used the
concentrations in tumor tissue, but you can just as well use the serum
concentrations.
I also develowed a second model which uses linear tumor growth and
considers resistance development over time, which is less pronounced if
concentrations of the anti-tumor drug increase. I've attached that code as =

well, maybe it is useful.
Considering the predictiveness of the model, in my case it seemed like the =

use of physiological life-span seemed to be a good corrector (I got the
idea from Monro, Drug Toxicokinetics: Scope and Limitations that Arise
from Species Differences in Pharmacodynamic and Carcinogenic Responses, J
Pharmacokin Biopharm 22, 41-57, 1994). I.e. if you want your patients to
survive 6 months, then use human average age of 75 years and mouse age of
2 years, so a mouse would have to survive 6 months/75*2= 5 days. But this=
 
might be different from drug to drug.

Best wishes
Nele

Simeoni:
$SUBROUTINES ADVAN6 TOL=3
$MODEL
  COMP=(GUT)
  COMP=(CENTRAL)
  COMP=(TUMOR)
  COMP=(PD)


$PK

TVCL=THETA(1)
CL=TVCL
;
TVV2=THETA(2)
V2=TVV2
;
TVKA=THETA(3)
KA=TVKA

TVF1=THETA(4)
F1=TVF1

TVPC=THETA(5)
PC=TVPC

TVKEO=THETA(6)
KEO=TVKEO

;
TVL0=THETA(7)
L0=TVL0*EXP(ETA(1))
;
TVL1=THETA(8)
L1=TVL1

TVK2=THETA(9)
K2=TVK2

W0=THETA(10)
F4=W0


S2=V2
K20=CL/V2
S4=1
PSI=20
;
$ERROR
  IPRED=F
  DEL=0
  IF (IPRED.EQ.0) DEL=0.0001
  W=F
  IRES=DV-IPRED
  IWRES=IRES/(W+DEL)
  Y=F+SQRT(THETA(12)*THETA(12)+THETA(11)*THETA(11)*F**2)*EPS(1)

;
$DES
DADT(1)= -KA*A(1)
DADT(2)= KA*A(1) -K20*A(2)
DADT(3)= KEO*(PC*A(2)/V2 - A(3))
DADT(4)= L0*A(4)/(1+(L0/L1*A(4))**PSI)**(1/PSI)-K2*A(3)*A(4)

own code:

$SUBROUTINES ADVAN8 TOL=3
$MODEL
  COMP=(GUT)
  COMP=(CENTRAL)
  COMP=(TUMOR)
  COMP=(PD)
  COMP=(AUC)

$PK

TVCL=THETA(1)
CL=TVCL*EXP(ETA(1))
;
TVV2=THETA(2)
V2=TVV2
;
TVKA=THETA(3)
KA=TVKA

TVF1=THETA(4)
F1=TVF1

TVPC=THETA(5)
PC=TVPC

TVKEO=THETA(6)
KEO=TVKEO

TVW0=THETA(7)
F4=TVW0
W0=F4 ; dataset: put a dummy dose of 1 into compartment 4, initial tumor=
 
weight is then estimated as F4

TVKRES=THETA(8)
KRES=TVKRES

TVIC50=THETA(9)
IC50=TVIC50

TVKIN=THETA(10)
KIN=TVKIN

TVRED=THETA(13)
RED=TVRED


S2=V2
K20=CL/V2
S4=1


;
$ERROR
  IPRED=F
  DEL=0
  IF (IPRED.EQ.0) DEL=0.0001
  W=F
  IRES=DV-IPRED
  IWRES=IRES/(W+DEL)
  Y=F+SQRT(THETA(12)*THETA(12)+THETA(11)*THETA(11)*F**2)*EPS(1)

;
$DES
CAV=A(5)/(T+0.01)
RES=IC50*EXP(KRES*T*(1-CAV/(RED+CAV)))
DADT(1)= -KA*A(1)
DADT(2)= KA*A(1) -K20*A(2)
DADT(3)= KEO*(PC*A(2)/V2 - A(3))
DADT(4)= KIN*(1-A(3)/(RES+A(3)))
DADT(5)= A(3)
_________________________
Dr. Nele Plock
Bayer Schering Pharma AG
Drug Metabolism & Pharmacokinetics
Development Pharmacokinetics
Scientific Expert Development Pharmacokinetics
D- 13342 Berlin

Phone : +49-30-468 15146
Fax: +49-30-468 95146
nele.plock_at_bayerhealthcare.com
http://www.bayerscheringpharma.de

Vorstand: Arthur J. Higgins, Vorsitzender | Werner Baumann, Andreas Busch, =

Ulrich Köstlin, Kemal Malik, Gunnar Riemann
Vorsitzender des Aufsichtsrats: Werner Wenning
Sitz der Gesellschaft: Berlin | Eintragung: Amtsgericht Charlottenburg 93
HRB 283



Patrick Zhou <patrickmzhou_at_yahoo.com>
Gesendet von: owner-nmusers_at_globomaxnm.com
06.01.2008 20:50

An
nmusers_at_globomaxnm.com
Kopie

Thema
[NMusers] PK/PD models to describe anti-ancer drug effect on the tumor
volume






Dear NMusers,
Does anyone aware any good published example (or non-public if you are
willing to share) of modeling the anti-cancer drug effect on the tumor
volume in nude mice model? And how this is normally used in the human dose =

projection, and any published work of such? Please advice. Thank you very =

much.
 
Patrick
 
 Be a better friend, newshound, and know-it-all with Yahoo! Mobile. Try it =

now.

Received on Mon Jan 07 2008 - 02:35:47 EST