;Model Desc: drug and metabolite study
;Project Name: POPPK
;Project ID: NO PROJECT DESCRIPTION

$PROB RUN# 101 
$INPUT C ID TIME AMT CMT DV MDV TYPE WT HT GEND AGE BMI RACE ADHE CFLU LFLU
$DATA DATA1.CSV IGNORE=C

$SUBROUTINE ADVAN7

$MODEL
   COMP=DEPOT
   COMP=CENTRAL
   COMP=METAB

$PK
   TVK12=THETA(1)
   K12=TVK12

   TVV2=THETA(2)*(WT/63.4)**1
   V2=TVV2

   TVCL=THETA(3)*(WT/63.4)**0.75
   CL=TVCL*EXP(ETA(1))

   TVV3=THETA(4)*(WT/63.4)**1
   V3=TVV3

   TVCL3=THETA(5)*(WT/63.4)**0.75
   CL3=TVCL3*EXP(ETA(2))

   K23=0.152*CL/V2
   K20=0.848*CL/V2
   K30=CL3/V3
   S2=V2/1000
   S3=V3/1000

$ERROR 

   TY=F

   IF (F.LT.0.001) TY=0.001
   IPRED=LOG(TY)
   LOQ=LOG(2)
       
   IF (CMT.EQ.2) SIG=SQRT(THETA(6)**2) 
   IF (CMT.EQ.3) SIG=SQRT(THETA(7)**2) 
   
   IF (TYPE.EQ.1) THEN
     F_FLAG=0
     Y=IPRED+SIG*EPS(1)
     IRES=DV-IPRED
     IWRES=IRES/SIG 
    ENDIF
   
   IF (TYPE.EQ.2) THEN
     F_FLAG=1
     Y=PHI((LOQ-IPRED)/SIG)
     IRES=0
     IWRES=0
   ENDIF

$THETA
33.6 FIX ; [K12] units - 1/day  
(0,3000) ; [V2] units - L
(0,500) ; [CL] units - L/day
(0,5000) ; [V3] units - L
(0,100) ; [CL3] units - L/day
(0,0.3) ; [THETA(6)] CV of the proportional RUV of parent drug
(0,0.1) ; [THETA(7)] CV of the proportional RUV of metabolite

$OMEGA BLOCK(2) 
0.09 ; [P] INTERIND VAR IN CL
0.05 ; [A]
0.09 ; [P] INTERIND VAR IN CL3

$SIGMA 1 FIX 

$EST MSF=101.MSF MAXEVAL=9999 PRINT=1 NOABORT METHOD=1 INTER LAPLACIAN POSTHOC SLOW NUMERICAL  
$COV SLOW

$TABLE ID TIME DV IPRED PRED CMT TYPE K12 V2 CL V3 CL3 SIG NOPRINT ONEHEADER FILE=101.TAB 
$TABLE ID TIME DV IPRED PRED CMT TYPE SIG RES IWRES WRES CWRES NPDE NOPRINT ONEHEADER FILE=sdtab101  
$TABLE ID K12 V2 CL V3 CL3 SIG ETA1 ETA2 NOPRINT ONEHEADER FILE=patab101
$TABLE ID WT HT AGE BMI NOPRINT ONEHEADER FILE=cotab101
$TABLE ID GEND RACE ADHE CFLU LFLU NOPRINT ONEHEADER FILE=catab101