Date: Fri, 02 Jul 1999 14:36:44 -0400 (EDT)
From: SRIRAM KRISHNASWAMI <Sriram.Krishnaswami@dupontpharma.com>
Subject: Drug-metabolite kinetics

Dear NM users

I am trying to simultaneously fit a drug and its metabolite concentrations. The drug can be modeled using a one-compartment model with 1st order absorption.

Can anybody give me suggestions as to how to model(syntax) the problem in NONMEM ?

Thanks

Sriram Krishnaswami

 

 

*****

 

 

From: "Bachman, William" <bachmanw@globomax.com>
Subject: RE: Drug-metabolite kinetics
Date: Fri, 2 Jul 1999 15:21:19 -0400

One way to do this is to define a reasonable model using differential equations based on what you know about the drug and the metabolite. E.g., a one compartmental model for the parent and possibly interconversion of parent to metabolite (does metabolism occur in central compartment, is metabolism reversible?, does the metabolite also follow one compartment dispostion?) One then needs to define a CMT data item to specify which compartment the observation corresponds to (central for the parent, some other for the metabolite based on the metabolite portion of the structural model you are proposing.)

Code might look something like this:

$PROBLEM 1comp,rev.metab,both elim. 7/2/99 WJB
$INPUT ID DOSE=AMT TIME DV CMT
$DATA d:\vnmdata\TEST\TESTy.PRN IGNORE=C
$SUBROUTINE ADVAN8 TRANS1 TOL=5
$MODEL NPAR=7 NCOMP=3 COMP=(DEPOT,DEFDOSE) COMP=(PARENT) COMP=(METAB)
$PK
KA= THETA(1) ;KA
VP= THETA(2) ;VP central vol. parent
CL= THETA(3) ;CL clearance parent
VMT=THETA(4) ;VMT central vol. metab
KF= THETA(5) ;KF parent->metab. conversion
KB= THETA(6) ;KB metab.->parent conversion
CLM=THETA(7) ;CLM clearance metab.

S2=VP ;SCALING FACTOR FOR PARENT IN CENTRAL COMP
S3=VMT ;SCALING FACTOR FOR METAB. IN CENTRAL COMP
$DES
DADT(1)=-KA*A(1)
DADT(2)=KA*A(1)-KF*A(2)+KB*A(3)-CL*A(2)/VP
DADT(3)=KF*A(2)-KB*A(3)-CLM*A(3)/VMT

$ERROR
W1=1
W2=F
IPRED=F
IRES=DV-IPRED
IWRES=IRES/(W1+W2)
Y=F + W1*ERR(1) + W2*ERR(2)

$THETA (0,2.5) ;1 KA
$THETA (0,35) ;2 VP
$THETA (0,0.75) ;3 CL
$THETA (0,15) ;4 VMT
$THETA (0,0.1) ;5 KF
$THETA (0,0.05) ;6 KB
$THETA (0,2.0) ;7 CLM
$OMEGA (1)(0.1)

$ESTIMATION PRINT=5 MAXEVAL=9999
$TABLE ID TIME CMT NOPRINT FILE=TESTy.PAR

Code not guaranteed to be 100% error free, but, it will give you a starting point. note: this is coded for individual dated, add etas for population data.

hope this helps,
Bill

William J. Bachman, Ph.D.
GloboMax LLC
Senior Scientist
7250 Parkway Drive, Suite 430
Hanover, MD 21076
Voice (410) 782-2212
FAX (410) 712-0737
bachmanw@globomax.com

 

*****

 

 

From: "BRUNO, Rene" <Rene.BRUNO@RP-RORER.FR>
Subject: RE: Drug-metabolite kinetics
Date: Mon, 5 Jul 1999 09:47:30 +0200

> Be careful I believe that this model may have identifiability problems. As
> it is written, CL (parent drug clearance should refer to clearance of all
> parent drug elimination routes except this particular metabolic route (it
> is accounted for by KF in the equation). In addition I don't think VMT is
> identifiable (as CLM) unless you know the fraction of parent drug
> converted to this particular metabolite (a problem similar for parent drug
> CL and VP in case of an oral drug, you need to know F, the absolute
> bioavailability).
>
An alternative code is this one (using ADVAN 6). The parent has 3 compartment IV route and the metabolite 2 compartments (compt 4 and 5) :

...
$SUBROUTINES ADVAN6 TRANS1 TOL=5
$MODEL
NCOMPARTMENTS=5 NPARAMETERS=10
COMP=(CENTRAL DEFDOSE NOOFF)
COMP=('PERIPH.' NOOFF)
COMP=('PERIPH.' NOOFF)
COMP=('METAB.' DEFOBS NOOFF)
COMP=('METAB.' NOOFF)

$PK
... ; parent parameters
TVK14=THETA(1)
K14=TVK14*EXP(ETA(1))
TVK45=THETA(2)
K45=TVK45*EXP(ETA(2))
TVK54=THETA(3)
K54=TVK54*EXP(ETA(3))
TVK40=THETA(4)
K40=TVK40*EXP(ETA(4))

K=CL/V ; K elimination for parent, all routes
S1=V ; Scaling for parent
S4=1 ; Scaling for the metabolite, should be V4 but it is unidentifiable since we don't know the fraction of parent CL accounted for by this metabolic route

$DES
DADT(1)=A(2)*K21+A(3)*K31-A(1)*(K12+K13+K) ; eq for parent
DADT(2)=A(1)*K12-A(2)*K21 ; eq for parent
DADT(3)=A(1)*K13-A(3)*K31 ; eq for parent
DADT(4)=A(1)*K14+A(5)*K54-A(4)*(K45+K40) ; eq for metabolite. As we fixed V4 = 1, then K14 estimate is actually K14/V4
DADT(5)=A(4)*K45-A(5)*K54 ; eq for metabolite

 

*****

 

 

From: "Bachman, William" <bachmanw@globomax.com>
Subject: RE: Drug-metabolite kinetics
Date: Tue, 6 Jul 1999 07:44:37 -0400

The code originally given mostly likely DOES HAVE IDENTIFIABILITY PROBLEMS (see caveat added). However, its intent was mainly didactic -> how to code a parent-metabolite. The details, of course, are dependent on the usual modeling constraints: does it reflect what we know about the drug?, is it "reasonable"?, does the data we have allow identification of defined parameters?, etc. Also, choice of ADVAN 6, 8 or 9 is, in the end, what works for your data and model.

Bill

William J. Bachman, Ph.D.
GloboMax LLC
Senior Scientist
7250 Parkway Drive, Suite 430
Hanover, MD 21076
Voice (410) 782-2212
FAX (410) 712-0737
bachmanw@globomax.com

 

 

*****

 

 

From: "Stephen Duffull" <sduffull@fs1.pa.man.ac.uk>
Subject: Re: Drug-metabolite kinetics
Date: Tue, 6 Jul 1999 13:29:38 +0100

Just a note.

Bill Bachman wrote:
>"reasonable"?, does the data we have allow identification
of defined
>parameters?, etc. Also, choice of ADVAN 6, 8 or 9 is, in
the end, what
>works for your data and model.

Don't rule out ADVAN 5 & 7 for linear PK models. I have often found them to be more "stable" than ADVAN 6 or 8 and quicker.

Regards
Steve
=====================
Stephen Duffull
School of Pharmacy
University of Manchester
Manchester, M13 9PL, UK
Ph +44 161 275 2355
Fax +44 161 275 2396