From: kmanouil@unmc.edu
Subject: Sequential absorption processes with lag time
Date: Thu, 4 Oct 2001 11:58:01 -0500

Dear NONMEM users,

I read discussion ?modeling fast and slow absorption? back to 1995.
Currently, I have similar type of problem.
There is one-compartment model with two absorption compartments linked
together by zero-order rate. A drug dosed in one of depot compartments.
Absorption from the second compartment had delay in a time.
So far I used ADVAN6 with two depot compartments and central compartment.
Despite, the fact that the problem was solved with WinNonlin,
I cannot figure out how to code time delay in NONMEM.
Can you help me with advice?

Konstantine Manouilov
Research Associate
University of Nebraska Medical Center

 

*****

 

 

From: "Piotrovskij, Vladimir [JanBe]" <VPIOTROV@janbe.jnj.com>
Subject: RE: Sequential absorption processes with lag time
Date: Mon, 15 Oct 2001 13:42:47 +0200

Konstantine,

You can try the following control which implements the sequential zero-order
-- first-order absorption with the lag time.

$PROBLEM Delayed absorption
$INPUT ID TIME AMT RATE CONC=DV
$DATA nmd.txt
$SUBROUTINES ADVAN2 TRANS2
$PK
CL = THETA(1) * EXP(ETA(1))
V = THETA(2) * EXP(ETA(2))
D1 = THETA(3) * EXP(ETA(3))
KA = THETA(4) * EXP(ETA(4))
ALAG1 = THETA(5) * EXP(ETA(5))
S2 = V
$ERROR CALLFL=0
IPRE = F
Y = IPRE * EXP(ERR(1))
$THETA
(0 3 10); 1 CL
(1 100 ); 2 V
(0 .5 5); 3 D1
(0 1 2); 4 KA
(0 .5 1); 5 ALAG
$OMEGA .1 .1 .1 .1 .1
1 2 3 4 5
$SIGMA .05
$EST MSFO=msf MAX=9990 PRINT=10 POSTHOC
$COV
$TABLE ID TIME AMT IPRE FILE=tab.txt NOPRINT ONEHEADER
$TABLE ID CL V D1 ALAG1 AMT FILE=prm.txt NOPRINT ONEHEADER NOAPPEND FIRST

An example of a (single-individual) data set is given below. It can be used
for simulations (DV variable is dummy). Note RATE = -2 for the dose record
to allow estimating zero-order absorption duration D1.

1 0 10 -2 0
1 0.1 0 0 1
1 0.2 0 0 1
1 0.5 0 0 1
1 1 0 0 1
1 2 0 0 1
1 4 0 0 1
1 8 0 0 1
1 16 0 0 1
1 24 0 0 1
1 48 0 0 1

Best regards,
Vladimir
------------------------------------------------------------------------

Vladimir Piotrovsky, Ph.D.
Research Fellow
Advanced Modelling and Simulations
Global Clinical Pharmacokinetics and Clinical Pharmacology (ext. 5463)
Janssen Research Foundation
B-2340 Beerse
Belgium
Email: vpiotrov@janbe.jnj.com