From: "Marie Du Preez" <du_preez@MED.UND.AC.ZA>

Subject: Control file

Date: 23 Sep 1998 11:44:41 -0400

I would like to know if anyone can supply me with a control file for running non-steady state IV data, one-compartment, first order and zero-order model. (NONMEM V)

Thank you

M du Preez

du_preez@med.und.ac.za

****

From: alison@c255.ucsf.EDU (ABoeckmann)

Subject: Re: Control file

Date: 24 Sep 1998 14:08:50 -0400

This question is a bit vague. Here are some general suggestions. I suggest using ADVAN2. In the data, include the CMT data item. A bolus dose to CMT 1 provides first-order input to the central compartment. A infusion dose to CMT 2 provides zero-order input to the central compartment.

E.G.,

$INPUT ID TIME CMT AMT RATE ....

In the data:

1 0 1 100 .

1 0 2 50 10

The first dose puts 100 units in cmt 1 at time 0, which then enters cmt 2 in a first-order process with rate constant KA.

The second dose is a zero-order input directly into cmt 2, 50 units, at the rate of 10 units per time unit.

The example can be made more elaborate. For instance,

The dose times need not be the same. There can be multiple doses of both types.

It is possible to model the rate or duration of the zero-order dose, by coding the RATE data item as -1 or -2, and then modelling R2 or D2 in the $PK block.

Bioavailabilty can be modelled for doses into cmt 1 (F1) or cmt 2 (F2).

Either or both doses can be lagged, by modelling ALAG 1 and/or ALAG2.

Using F1, F2 and ALAG1 or ALAG2, it is possible to model a combined absorption process in which a single dose has both a zero order and a first order phase, such that two bioavailabilities add to unity.

****

From: "Marie Du Preez" <du_preez@MED.UND.AC.ZA>

Subject: Control file

Date: 25 Sep 1998 07:16:50 -0400

Dear Alison,

Re: Control file for first- and zero order elimination

Thank you very much for the prompt reply.

I agree that my question was vague and would like to state it again.

I have non-steady state IV data with a loading dose and maintenance doses in neonates with very slow elimination. I suspect non-linearity in elimination at higher doses. Therefore, I am looking for a control file to model parallel first- and zero-order elimination.

Thank you very much.

M du Preez

du_preez@med.und.ac.za

****

From: Etienne Chatelut <chatelut@icr.fnclcc.fr>

Subject: Re: Control file for first- and zero order elimination

Date: 25 Sep 1998 09:36:15 -0400

Dear Mrs Du Preez,

Please find below the control-stream we use to model parallel first- and saturable (Michaelis-Menten) (iv administration) elimination:

$PROB ADVAN6

$INPUT ID CYCL TIME DV AMT RATE EVID MDV

$DATA icrc1

$SUBROUTINES ADVAN6 TRANS1 TOL=4

$MODEL COMP=(CENTRAL,DEFOBS)

$PK

V=THETA(1)*EXP(ETA(1))

K10=THETA(2)*EXP(ETA(2))

VM=THETA(3)*EXP(ETA(3))

KM=THETA(4)*EXP(ETA(4))

S1=V

$DES

C1=A(1)/S1

DADT(1)=-K10*A(1)-C1*VM/(KM+C1)

$THETA (5,10,100) (0,.1,10) (40,50,150) (.05,.1,.2)

$OMEGA .25 1 .25 .25

$ERROR

DEL=0

IF (F.EQ.0) DEL=1

W=F+DEL

Y=F*(1+ERR(1))+ERR(2)

IPRED=F

IRES=DV-IPRED

IWRES=IRES/W

$SIGMA 0.04 .05

$EST MAXEVALS=9000 POSTHOC

$TABLE ID TIME DV IPRED VM KM V K10

$SCATTERPLOT PRED VS DV