From: "nelamangala nagaraja" <nvnagaraj@hotmail.com>
Subject: INITIAL OBJ FUNCTION ERROR
Date: Wed, 05 Apr 2000 01:00:15 EDT

Dear NM Users,

I am fitting a dataset with parent drug (actually a prodrug) and its metabolite, both following a 2-compartment model and present in plasma and CSF. I am using ADVAN6 for modeling. When I started nonmem execution, it was immediately terminated with the following message in the output file:

MONITORING OF SEARCH:

0PROGRAM TERMINATED BY OBJ
ERROR IN CELS WITH INDIVIDUAL 5 ID= .50000000E+01
WEIGHTED SUM OF "SQUARED" INDIVIDUAL RESIDUALS IS INFINITE
MESSAGE ISSUED FROM ESTIMATION STEP
AT INITIAL OBJ. FUNCTION EVALUATION

The control file is as follows

$PROBLEM PRODRUG AND DRUG IN PLASMA AND CSF
$INPUT ID TIME AMT DV RATE CMT MDV
$DATA MPHSMPPC1.CSV IGNORE=C

$SUBROUTINE ADVAN6 TRANS 1 TOL=3
$MODEL
COMP=(CENTRAL1)
COMP=(PERIPH1)
COMP=(CENTRAL2)
COMP=(PERIPH2)
COMP=(CSF1)
COMP=(CSF2)


$PK
TVCL1 = THETA(1)
TVV1 = THETA(2)
K12A = THETA(3)
K21A = THETA(4)
TVCL2 = THETA(5)
TVV2 = THETA(6)
K34A = THETA(7)
K43A = THETA(8)
KF = THETA(9)
K12B = THETA(10)
K21B = THETA(11)
K34B = THETA(12)
K43B = THETA(13)


CL1=TVCL1*EXP(ETA(1))
V1=TVV1*EXP(ETA(2))
CL2=TVCL2*EXP(ETA(3))
V3=TVV2*EXP(ETA(4))
S1=V1
S3=V3
S5=0.125
S6=0.125
K1=CL1/V1
K2=CL2/V3

$DES
DADT(1)=-(K1-KF)*A(1)+ K21A*A(2)-K12A*A(1)-K12B*A(1)+K21B*A(5)
DADT(2)=-K21A*A(2)+K12A*A(1)
DADT(3)=KF*A(1)-K2*A(3)-K34A*A(3)+K43A*A(4)-K34B*A(3)+K43B*A(6)
DADT(4)=K34A*A(3)-K43A*A(4)
DADT(5)=K12B*A(1)-K21B*A(5)
DADT(6)=K34B*A(3)-K43B*A(6)

$THETA
(0.001, 18)
(0.001, 22)
(0.0001, 1.5)
(0.0001, 0.8)
(0.0001, 20)
(0.001, 30)
(0.001, 1.1)
(0.001, 1.2)
(0.0001, 0.45)
(0, 0.01)
(0, 0.012)
(0, 0.015)
(0, 0.011)


$OMEGA
0.1 ; FOR CL1
0.1 ; FOR V1
0.15; FOR CL2
0.12; FOR V3



$ERROR
R1=0
IF (CMT.EQ.1) R1=1
R2=0
IF (CMT.EQ.3) R2=1
R3=0
IF (CMT.EQ.5) R3=1
R4=0
IF (CMT.EQ.6) R4=0

Y1=F+EPS(1)
Y2=F+EPS(2)
Y3=F+EPS(3)
Y4=F+EPS(4)


Y=R1*Y1+R2*Y2+R3*Y3+R4*Y4

IPRED=F
IRES=DV-IPRED

$SIGMA 0.1 0.2 0.01 0.01


$ESTIMATION METHOD=0 MAXEVAL=9999 PRINT=5
$TABLE ID TIME AMT CL1 V1 K12A K21A CL2 V3 K34A K43A KF K12B K21B K34B K43B
NOPRINT ONEHEADER FILE=MPHSMPPC1B


I tried to use both additive and exponential error models Could you please suggest a solution for this.

Thanks

Raj

N.V. Nagaraja
Post Doc Res Assoc
Department of Pharmaceutics,
University of Florida,
Gainesville, FL-32610
Ph: 352-846-3257
Fax: 352-392-4447

 

 

*****

 

 

From: "Piotrovskij, Vladimir [JanBe]" <VPIOTROV@janbe.jnj.com>
Subject: RE: INITIAL OBJ FUNCTION ERROR
Date: Wed, 5 Apr 2000 07:58:40 +0200

Dear Raj,
Recently, I and a colleague of mine had the same problem with a much simpler model. I have no explanation yet, but what we did to obviate the problem was log-transformation of concentrations and fitting the model to logarithms (F in the $ERR block was also log-transformed). The residual error model was additive. Contact me if you need more details on the implementation.

Best regards,
Vladimir

 

*****

 

 

From: j.dejongh@lapp.nl
Date: Wed, 5 Apr 2000 09:43:25 +0200
Subject: RE: INITIAL OBJ FUNCTION ERROR

Dear Vladimir, Raj & other NM users,
I thought that this kind of error message might also be an indication for reconsideration of the initial theta values.

best regards,
Joost DeJongh

Dr. Joost DeJongh
Leiden Advanced Pharmacokinetics & Pharmacodynamics (LAP&P) Consultants
Archimedesweg 31
2333 CM Leiden
The Netherlands
Phone: + 71 568 6920
fax: + 71 568 6972

 

 

*****

 

 

Date: Wed, 05 Apr 2000 09:49:11 +0200
From: Mats Karlsson <Mats.Karlsson@biof.uu.se>
Subject: Re: INITIAL OBJ FUNCTION ERROR

The reason for the problem is that for observations related to compartment 6, there model predicts that the residual error magnitude is zero (because of a typo, see below).
> R4=0
> IF (CMT.EQ.6) R4=0

Best regards,
Mats Karlsson
--
Mats Karlsson, PhD
Professor of Biopharmaceutics and Pharmacokinetics
Div. of Biopharmaceutics and Pharmacokinetics
Dept of Pharmacy
Faculty of Pharmacy
Uppsala University
Box 580
SE-751 23 Uppsala
Sweden
phone +46 18 471 4105
fax +46 18 471 4003
mats.karlsson@biof.uu.se