From: Partha Nandy partha.nandy@bms.com
Subject:[NMusers] Changing Clearance over time : Enzyme auto-induction
Date: Fri, August 6, 2004 2:46 pm

Hi All,

I am trying to model the kinetics of a drug that exhibits enzyme 
auto-induction.  From the data it seems that for the first few days 
there is no effect on the enzyme, as evidenced from the accumulation 
factor.  But slowly the induction sets in.  To model the change in 
clearance, I am using a Emax model for CL;  CL=CL0+CLmax*t/t50+t.  I 
have used appropriate hill function as well, but my predicted 
concentrations are systematically lower than those observed at the 
earlier time points.

Can any one help me with  modeling the CL  where  the  CL value will  
remain constant up to a time 'X', the critical time (preferably 
expressed as THETA) after which the non-linear function will kick-in.

Your help is greatly appreciated.

Regards,
Partha

Partha Nandy
Clinical Discovery
BMS-Lawrenceville, NJ
_______________________________________________________

From: "Bhattaram, Atul" BhattaramA@cder.fda.gov
Subject: RE:[NMusers] Changing Clearance over time : Enzyme auto-induction
Date: Fri, August 6, 2004 3:01 pm 

Hello Partha

Did you refer to this link? It has a reference which could help you.

http://www.cognigencorp.com/nonmem/nm/97may142001.html


Venkatesh Atul Bhattaram
Pharmacometrics
DPE-1, OCPB, FDA
_______________________________________________________

From: Leonid Gibiansky lgibiansky@emmes.com
Subject: RE:[NMusers] Changing Clearance over time : Enzyme auto-induction
Date: Fri, August 6, 2004 3:11 pm   

Have you tried straightforward:

NewT = T-theta(*)
CL = CL0
IF(NewT.GT.0) THEN
       CL = CL0 + CLmax*NewT/(t50+NewT)
ENDIF

Leonid
_______________________________________________________

From: Johan.Gabrielsson@astrazeneca.com
Subject: RE:[NMusers] Changing Clearance over time : Enzyme auto-induction
Date: Mon, August 9, 2004 1:59 am

Dear Partha, Leonid et al,

Interesting discussion. May I propose a first-order induction function
(since often enzyme reactions can be approximated to that) as an alternative
to the previously proposed models. Namely,

CL = CLinduced -(CLinduced - CLpre)*exp(-kout*(t-Tlag))

where kout corresponds to the fractional turnover rate of the induced
enzyme, CLpre the pre-induction clearance (your CL0 I suppose), CLinduced
the clearance at steady-state post-induction, and Tlag the lag-time for
induction to occur (I suppose your NewT parameter). I have personally
applied this relationship (taken from the textbook of Gibaldi and Perrier
1982, pgs. 304-305) at several occassions. The nice thing about the model is
that it gives you some info about the apparent fractional turnover-rate (and
turnover time) of the inducing enzyme, provided the rate limiting step is
the change of the amount of enzyme rather than the half-life of the drug
(T1/2kout >> T1/2K(drug)) and that the turnover rate (production) rather
than the fractional turnover rate (loss) of enzyme is affected.

I have some documented practical examples of simultaneous pre-, peri- and
post-induction modelling after repeated dosing (p.o. and i.v.), that I'll be
happy to share if you are interested.

:-)

Johan
_______________________________________________________

From: "Mats Karlsson" 
Subject: RE:[NMusers] Changing Clearance over time : Enzyme auto-induction
Date: Mon, August 9, 2004 3:23 am
 
Dear Partha,

I agree with Johan that a more physiological model is often preferable.
Taking it one step further is to make the magnitude of induction graded.
It may be reasonable to make it dependent on the plasma drug
concentration. Code for such a model is given below. Also, there may be
both inducible and uninducible pathways of elimination for a drug. If
you have metabolite data you need to take this into account. We used
such a model in:

Hassan M et al.. A mechanism-based pharmacokinetic-enzyme model for
cyclophosphamide autoinduction in breast cancer patients.
Br J Clin Pharmacol. 1999 Nov;48(5):669-77.

With this model, you don't need to make any assumption about relative
rates of drug and enzyme turn-over. 

If it takes some time before the induction is becoming apparent, it can
be modeled with a lagtime, but on the other hand, a lagtime is not
particularly physiological. One solution that Toufigh Gordi and I have
used is to include a precursor into the chain of events (ie drug induces
production of precursor which in turn increases the rate of enzyme
production), the turn-over of the precursor will determine the delay in
appearance of observable induction.

Best regards,
Mats

$PROBLEM   Cyklophosfamid induction (drug + metabolite)
$INPUT     DROP ID TIME DV NEWA AMT RATE CMT FLAG DURA
$DATA       cp11.dta  IGNORE=#
$SUBROUTINES ADVAN9 TOL=6
$MODEL COMP=CENTRAL
       COMP=PERI
       COMP=4OH
       COMP=ENZ
$PK
CLUI = THETA(1)*EXP(ETA(1))
CLI  = THETA(2)
V1   = THETA(3)*EXP(ETA(2))
Q    = THETA(4)*EXP(ETA(3))
V2   = THETA(5)*EXP(ETA(4))
CLOH = THETA(6)*EXP(ETA(5))
VOH  = THETA(7)
EMAX = THETA(8)*EXP(ETA(6))
EC50 = THETA(9)
KENZ = THETA(10)
S1   = V1
S3   = VOH
K10  = CLUI /V1
K12  = Q    /V1     
K13  = CLI  /V1
K21  = Q    /V2
K30  = CLOH /VOH
$DES
CP     = A(1)/V1
DADT(1)=-A(1)*(K10+K12+K13*A(4)) + K21*A(2)
DADT(2)= A(1)*     K12           - K21*A(2)
DADT(3)= A(1)*A(4)*    K13       - K30*A(3)
DADT(4)= KENZ*(1+EMAX*CP/(CP+EC50)-A(4))
$THETA   
         (0,1.14 )  ;CLUI
         (0,1.76 )  ;CLI
         (0,9.75 )  ;V1
         (0,12.6 )  ;Q
         (0,21.5 )  ;V2
         (0,300)    ;CLOH
         (0,30 )    ;VOH
         (0,306)    ;EMAX
         (0,5540 )  ;EC50
         (0,.0279 ) ;KENZ
         (0,1.38 )  ;ADD ERROR
         (0,.0642 ) ;PROP ERROR
         (0,.03)    ;ADD ERROR
         (0.05,.13) ;PROP ERROR
$OMEGA .0556 .267 .41 .219 .06 .232 

$ERROR
     W           = 1
     IF(F.GT.0) W=              SQRT(THETA(11)**2+THETA(12)**2*F**2)

     IF(F.GT.0.AND.CMT.EQ.3) W= SQRT(THETA(13)**2+THETA(14)**2*F**2)

     IPRED       = F
     IRES        = DV-IPRED
     IWRES       = IRES / W
     Y           = IPRED+EPS(1)*W

$SIGMA  1 FIX    ;RESIDUAL ERROR 
$ESTIMATION MAXEVALS=9990 METH=1 INTER PRINT=1 MSFO=msfb99 
$COV
$TABLE ID TIME IPRED IWRES      ONEHEADER NOPRINT FILE=sdtab99
$TABLE ID FLAG TIME IPRED IWRES ONEHEADER NOPRINT FILE=mutab99
$TABLE ID CLUI CLI V1 Q V2 CLOH VOH EMAX 
                                ONEHEADER NOPRINT FILE=patab99
$TABLE ID ETA1 ETA2 ETA3 ETA4 ETA5 ETA6
                            ONEHEADER NOPRINT FILE=mytab99
--
Mats Karlsson, PhD
Professor of Pharmacometrics
Div. of Pharmacokinetics and Drug Therapy
Dept. of Pharmaceutical Biosciences
Faculty of Pharmacy
Uppsala University
Box 591
SE-751 24 Uppsala
Sweden
phone +46 18 471 4105
fax   +46 18 471 4003
mats.karlsson@farmbio.uu.se
_______________________________________________________