From: Paul Hutson <prhutson@pharmacy.wisc.edu>

Subject: Averaged peripheral concentration

Date: Fri, 24 Aug 2001 13:20:51 -0500

 

I am analyzing the PK of topotecan in the context of concurrent radiation

treatment wherein the effect of the XRT is irreversible and possibly

concentration dependent. I am trying to compare the effect (tox and

efficacy) of the XRT as a function of the concentration of the drug in

either of the central and peripheral compartments. Although AUC is

downplayed in the thread 99feb042000.html on the NONMEM repository, the

average amount (AUC*V2/(TIMExrt-stop - TIMExrt-start)) of topotecan in the

peripheral compartment during radiation is a rational variable to evaluate

(says me). As the control stream below indicates, I am using $DES In

addition to fitting general poppk for an antineoplastic drug. The

generation and tabulation of amount A(2) in the peripheral

compartment with subsequent trapezoidal summation in a spreadsheet is

doable, but not very elegant. If included in a NONMEM control stream, does

this require the use of a (3 x N) array for Time, PeripheralAmt, and

cumulative AUC? Suggestions are welcome; haven't had to use arrays much

before. Thanks.

Paul

 

$PROBLEM TOPOTECAN FINAL 2 CHECKOUT

$INPUT ID DATE=DROP TIME DV AMT RATE ADDL II WGT HT AGE SCR UVOL CMT

WEEK PT ETHY LEVL GEN EVID

$DATA TOPOXRT.TXT IGNORE=C

 

$SUBROUTINE ADVAN6 TRANS1 TOL=5

$MODEL NPAR=5 NCOMP=3 COMP=(CENTRAL,DEFDOS,DEFOBS) COMP=(PERIPH) COMP=(OUT)

; COMP 3 REFLECTS URINE COLLECTION

$PK

;CALCULATES BSA

BSA=(HT*WGT/3600)**0.5

;CALCS HT ABOVE 5FT (IN CM)

THT=(HT-152.4)/2.54

;CALCS IDEAL BODY WEIGHT BY GENder

;Males = 0; Female = 1

IBW=45 - 5*(GEN-1)+(2.3*THT)

DWGT=IBW

;USES ACTUAL WGT IF < IDEAL WGT

IF(IBW.GT.WGT) DWGT=WGT

;CALCS CREATININE CLEARANCE

TAGE=140-AGE

CLCR=(TAGE*IBW*0.85**GEN)/(72*SCR)

 

KREN=THETA(1)*CLCR/100; K10-RENAL, 100 TAKEN AS USUAL CLCR

KNREN=THETA(2); K10-NONRENAL

K12=THETA(3); K12

K21=THETA(4); K21

K10=KREN+KNREN

 

TVV1=THETA(5);*BSA

V1=TVV1*EXP(ETA(1))

CLREN=KREN*V1*EXP(ETA(2))

CLNREN=KNREN*V1*EXP(ETA(3))

CL=CLREN+CLNREN

TVQ=K12*V1;*BSA

Q=TVQ*EXP(ETA(4))

TVV2=(K12/K21)/V1;*BSA

V2=TVV2*EXP(ETA(5))

S1=V1

 

TEOI=TIME-RATE/AMT; REPORTS TIME SINCE END OF INFUSION

IF (TEOI.LT.0) TEOI=0

 

IF (ABS(ETA(1)).GT.10) EXIT 1 100

IF (ABS(ETA(2)).GT.10) EXIT 1 200

IF (ABS(ETA(3)).GT.10) EXIT 1 300

IF (ABS(ETA(4)).GT.10) EXIT 1 400

IF (ABS(ETA(5)).GT.10) EXIT 1 500

 

$DES

DADT(1)=-(K10+K12)*A(1)+K21*A(2)

DADT(2)=K12*A(1)-K21*A(2)

 

A1=A(1); AMT IN CENTRAL COMPARTMENT

A2=A(2); AMT IN PERIPHERAL COMPT

 

$ERROR

FX=0

IF (F.EQ.0) FX=1

W=F+FX

IPRED=F

IRES=DV-IPRED

IWRES=IRES/W

 

IF (CMT.EQ.1) Y=IPRED+W*ERR(1); CENTRAL (SAMPLED) CMPT

IF (CMT.EQ.2) Y=IPRED+W*ERR(2); PERIPHERAL CMPT

IF (CMT.EQ.3) Y=IPRED+W*ERR(3); URINE

 

$THETA (0.01,1,1000); KREN

$THETA (0.01,1,1000); KNONREN

$THETA (0.01,1.5,1000); K12

$THETA (0.01,1.5,1000); K21

$THETA (0.1,50,1000); V1

$OMEGA 1 1 1 1 1

$SIGMA .25 .25 .25

 

;$EST MAXEVAL=4000 NSIG=3 PRINT=10 METHOD=0 NOABORT

;$EST MAXEVAL=4000 NSIG=3 PRINT=10 METHOD=1 NOABORT

;$COV

$TABLE ID TIME IPRED IWRES NOPRINT ONEHEADER FILE=sdtab2

$TABLE ID CL V1 Q V2 TEOI A2 ETA1 ETA2 ETA3 ETA4 ETA5 NOPRINT ONEHEADER

FILE=patab2

Paul Hutson, Pharm.D.

Associate Professor (CHS)

UW School of Pharmacy

NOTE NEW ADDRESS effective 6/2001

777 Highland Avenue

Madison, WI 53705-2222

Tel: (608) 263-2496

FAX: (608) 265-5421

Pager: (608) 265-7000, #7856