From: Daniel MAZUIR florent.mazuir@wanadoo.fr
Subject:[NMusers] help needed - nonlinear absorption
Date: Tue, July 6, 2004 10:19 am

Dear NMusers,

I am a trainee from Paris Pharmacy School .
I'm currently working on a compound presenting
a non linear absorption profile and it would be
very helpful for me if you could provide an example
of a simple NONMEM control file with the non
linearity you would implement for absorption. My
compound has a zero order Absorption.

If not, could you please just tell me if the code
has to be written in $PRED or if it could be run
with "only" $PK, $DES and ADVAN6or 8??

Many thanks in advance for your help,

Florent.
_______________________________________________________

From: "Bachman, William (MYD)" bachmanw@iconus.com
Subject: RE:[NMusers] help needed - nonlinear absorption
Date: Tue, July 6, 2004 11:33 am

Daniel,
 
In general, use $PRED when you have an analytical solution
for your model (closed form equations).  Use $DES, when your
model is in terms of differential equations.  You may also
"approximate" nonlinear absorption using a standard advan and
$PK by making the absorption parameter in your model a function
of the dose.  
 
I'm not sure whether you were inferrring that your compound has
nonlinear absorption or nonlinear kinetics, but, here is an
example of a nonlinear model for absorption (saturable absorption)
using $DES follows:
 
;Model Desc: saturable absorption
;Project Name: LIBRARY
;Project ID: PdxPop

$PROB RUN# 001
$INPUT ID AMT TIME DV CMT 
$DATA mm2.csv IGNORE=C
$SUBROUTINE ADVAN6 TRANS=1 TOL=3
$MODEL NCOMP=2
COMP=(GUT)
COMP=(CENTRAL)

$PK
VM=THETA(1)*EXP(ETA(1))
KM=THETA(2)*EXP(ETA(2))
CL=THETA(3)*EXP(ETA(3))
V2=THETA(4)*EXP(ETA(4))
S2=V2

$DES
DADT(1)=-VM*A(1)/(KM+A(1))
DADT(2)= VM*A(1)/(KM+A(1))-CL*A(2)/V2

$ERROR
Y=F + F*ERR(1)

$THETA 
(0,10) ;[VM]
(0,1)   ;[KM]
(0,25) ;[CL]
(0,50) ;[V2]

$OMEGA 
0.04;[P]
0.04;[P]
0.04;[P]
0.04;[P]
$SIGMA
0.1 ;[P]
$EST MAX=1000 PRINT=5
;$COV
$TABLE ID TIME AMT CMT FILE=MM2.tab

William J. Bachman, Ph.D. 
Manager, Pharmacometrics Research and Development 
GloboMax® 
The Strategic Pharmaceutical Development Division of ICON plc 
7250 Parkway Drive, Suite 430 
Hanover, MD 21076 
410-782-2212 
bachmanw@iconus.com 
_______________________________________________________