From:"Kakkar, Tarundeep" 
Subject:[NMusers] 2-cmpt PK model using ADVAN6
Date:Thu, 13 Jun 2002 15:17:26 -0400

Hi,

I'm trying to write a differential model using ADVAN6.  However, I can't get
it to converge.  I had initially fitted the same data to ADVAN4 TRANS4 and
the fits were fine.  Also, when I tried to simulate using POSTHOC estimates
from the ADVAN4 fit, I got very different numbers.  The model and input
files are as follows:

$PROB 
$INPUT C DROP=ID TIME DV AMT II ADDL SS CMT
$DATA PK.csv IGNORE=C
$SUBROUTINE ADVAN6 TRANS=1 TOL=6
$MODEL NCOMP=3
  COMP=(GUT)
  COMP=(CENTRAL)
  COMP=(PERIPH)
  

$PK

;PK parameters
 TVCL=THETA(1)
 TVV1=THETA(2)
 TVQ=THETA(3)
 TVV2=THETA(4)
 TVKA=THETA(5)
 
 CL=TVCL
 V2=TVV1
 Q=TVQ
 V3=TVV2
 KA=TVKA

  
 
$DES
 C2=A(2)/V2
 C3=A(3)/V3
 DADT(1)=-KA*A(1)
 DADT(2)=KA*A(1)+Q*(C3-C2)-CL*C2
 DADT(3)=Q*(C2-C3)
 
 

$ERROR
 
 Y=F*(1+ERR(1))



$THETA (30) ;CL
       (780) ;V2
       (1.09) ;Q
       (141) ;V3
       (1.45) ;KA
       
$OMEGA 0.1      


$ESTIMATION MAXEVAL=9999 METHOD = 1 PRINT=1 NOABORT 

;$COV
;$TABLE TIME DV PRED CL V2 Q V3 KA FILE=PK.tab NOPRINT ONEHEADER

C,ID,TIME,DV,AMT,II,ADDL,SS,CMT
,1,0,.,19500,12,17,.,1
,1,2,23.8,.,.,.,.,2
,1,3,20.6,.,.,.,.,2
,1,4,20.1,.,.,.,.,2
,1,6,19.9,.,.,.,.,2
,1,12,14,.,.,.,.,2
,1,48,28,.,.,.,.,2
,1,192,34.3,.,.,.,.,2
,1,216,37.1,.,.,.,.,2
,1,216,.,19500,12,.,1,1
,1,218,58.3,.,.,.,.,2
,1,219,71.4,.,.,.,.,2
,1,220,56.4,.,.,.,.,2
,1,222,54.7,.,.,.,.,2
,1,228,40.2,.,.,.,.,2
,1,264,8.03,.,.,.,.,2
,1,312,1.99,.,.,.,.,2

Thanks in advance for your help.

Tarun


*******

From:"Bachman, William" 
Subject:RE: [NMusers] 2-cmpt PK model using ADVAN6
Date:Thu, 13 Jun 2002 15:42:38 -0400

Tarun,

At first glance, all that seems to be missing is a scaling factor:

S2=V2

Bill