From: Toufigh Gordi <tgordi@buffalo.edu>
Subject: [NMusers] PRED in a Hill binding model
Date: 6/18/2003 5:06 PM
Dear all,

I have a simple cell binding model (Hill equation). The PK parameters
where estimated separately and then individual PK estimates (2-comp,
nonlinear CL) were fixed (entered in the underlying PD data set). The
model file is given below. It works nicely and gives reasonbale estimates
of the parameters. One thing that puzzles me, however, is that the population
predictions (PRED) are NOT the same for subjects in the same dose group (6
subjects each in 6 different single dose groups). The question is then, what
PRED is and also how I get the population estimates?

Regards,

Toufigh Gordi


$PROB ALL DOSES
; 2-COMP
$INPUT ID AMT RATE DUR DATE=DROP TIME DV EVID SEXF CMT GRP PKPD PKKM
PKVM PKV1 PKQ PKV2 PKE1 PKE2
$DATA pd.csv IGNORE=#
$SUBROUTINE ADVAN6 TRANS1 TOL=5
$MODEL NCOMP=2

COMP=CENT
COMP=PERIPH

$PK

       VM=PKVM*EXP(PKE1)
       KM=PKKM
       V1=PKV1*EXP(PKE2)
       Q=PKQ
       V2=PKV2
       D1=DUR
       S1=V1
       BASE=THETA(1)
       IMAX=THETA(2)*EXP(ETA(1))
       IC50=THETA(3)*EXP(ETA(2))
       HILL=THETA(4)

$DES
CON=A(1)/V1
DADT(1)=-A(1)*(VM/(KM+CON))/V1-A(1)*Q/V1+A(2)*Q/V2
DADT(2)=A(1)*Q/V1-A(2)*Q/V2

$ERROR
       CONC=F
       LAM=BASE-(IMAX*(CONC**HILL)/(IC50**HILL+(CONC**HILL)))
       Y=LAM*(1+EPS(1))+EPS(2)

$THETA (0, 62, 100)    ;1 BASE
$THETA (0, 60)            ;2 IMAX
$THETA (0, 0.7)           ;3 IC50
$THETA (0, 1)              ;4 HILL

$OMEGA 0.1             ;2 IIV BMAX
$OMEGA 0.1             ;3 IIV IC50

$SIGMA 0.1             ;1 PROP ERROR
$SIGMA 0.1             ;2 ADD ERROR

$ESTIMATION NOABORT POSTHOC MAXEVAL=9999 PRINT=3 METHOD=1 MSFO=MSF2508
$COVARIANCE
$TABLE ID TIME Y PKPD                 NOPRINT ONEHEADER FILE=SDTAB2508
$TABLE ID TIME BASE IMAX IC50 HILL ETA1 ETA2
NOPRINT ONEHEADER FILE=PATAB2508
$TABLE ID SEXF                        NOPRINT ONEHEADER FILE=CATAB2508
$TABLE ID GRP                         NOPRINT ONEHEADER FILE=COTAB2508




_______________________________________________________

From: Leonid Gibiansky <lgibiansky@emmes.com>
Subject: Re: [NMusers] PRED in a Hill binding model
Date: 6/18/2003 5:29 PM

You mentioned that you use INDIVIDUAL PK parameters, so although your
PD parameters are the same for the entire population, the model uses
individual concentrations. Therefore, effect that depend on concentration
differ from subject to subject. To get population estimates, you either
need to fit a joint PK/PD model, or introduce fictitious "average" patient
with population PK parameters, or add PD part (with fixed parameters) into
your PK model and compute it there.

Leonid

_______________________________________________________