From: Kakkar, Tarundeep [mailto:tarundeep.kakkar@spcorp.com]
Subject: PK/PD problem using ADVAN6
Date: Friday, March 01, 2002 8:09 AM

Hi,

I sent a question to nmusers.  Someone suggested that the model needs ERR(1)
rather than ETA(1) for the $OMEGA for the single subject and I should go
with population modeling straightaway.  I went and did that, but I'm not
getting satisfactory results, the model converges but the fit isn't correct.
The PD measurements should start coming back at later time-points according
to the observed data, but in the fit the PD keeps on going down.  

So, I'm forwarding the email I sent to the nmusers group.  Is there
something wrong the way I coded the data file?  Does it need a fictitious
compartment  (CMT = 2).  Does having AMT =1 at the 0 hr value for CMT=3
somehow messes it up?

I hope you can help me.

Tarun


I am trying to fit an Indirect response model to a
drug given orally once a week.  There are no PK
measurements.  I have a baseline value for each
subject and PD measurements every week for 28 days (0,
7, 14, 21 and 28 days).   I'm trying to troubleshoot
this with one subject before I go to fitting all
subjects and am having problems with the model
converging.  
I don't know if the data file is setup incorrectly or
if the model is incorrect or both.  Is it
overparameterized (4 estimates and only 5 observed
values)?  If it's overparametrized, how do I force it
to not estimate ETA(1)? 

I was able to get a decent fit for this in WinNonlin. 
I would really appreciate if someone could help me
with this.

Thanks

Tarun

The model I wrote goes something like this (Time in
hours):

$PROB POP PK/PD Model  $DES
$INPUT ID VOL TIME DV AMT CMT 
$DATA data.csv IGNORE=C
$SUBROUTINE ADVAN6 TRANS=1 TOL=3
$MODEL NCOMP=3
  COMP=(GUT)
  COMP=(CENTRAL)
  COMP=(EFFECT)

$PK
 KA=0.042
 KE=0.022
 V2=VOL
 S2=V2
  
 IC50=THETA(1);*EXP(ETA(1))
 KOUT=THETA(2);*EXP(ETA(3))
 KIN=THETA(3);*EXP(ETA(2))

 F3=KIN/KOUT
  
$DES
 DADT(1)=-KA*A(1)
 DADT(2)=KA*A(1)-KE*A(2)
 CE=A(2)/V2
 DRUG1=1-CE/(CE+IC50)
 DADT(3)=KIN*DRUG1-KOUT*A(3)

$ERROR

Y=F+ETA(1)
IPRED=F

 and so on ....

Data file:

CID        VOL        TIME        DV        AMT        CMT        
1        91.825        0        .        3000000        1        
1        91.825        0        .        1        3        
1        91.825        0        43916        .        3        
1        91.825        168        .        3000000        1        
1        91.825        168        16638        .        3        
1        91.825        336        .        3000000        1        
1        91.825        336        3349        .        3        
1        91.825        504        .        3000000        1        
1        91.825        504        6183        .        3        
1        91.825        672        .        3000000        1        
1        91.825        672        5707        .        3        



***************************************************************
 This message and any attachments is solely for the intended recipient. If
you are not the intended recipient, disclosure, copying, use, or
distribution of the information included in this message is prohibited --
please immediately and permanently delete this message.

*******

From:"Bachman, William"   
Subject:[NMusers] PK/PD problem using ADVAN6 [GM000245]  
Date:Fri, March 1, 2002 4:58 pm  


Tarun,

I got a reasonable fit to your data for one individual with minor
modifications to your control stream and data file. 

the data file:

The dose to cmt 3 constitutes setting the initial condition in cmt 3.  As
such, instead of "1" it should be a number reflecting the steady state
effect in the absence of drug, KIN/KOUT.  You may use the observed effect at
time zero if that's all you have (or an average baseline value prior to
dosing).  I used the observed effect at time zero here for the "dose" to cmt
3.  Alternatively, model KIN as a steady state infusion, R3 (see Manual
VIII, Exogenous Supplementation Example, p. 312).
(I also modified the data (added a leading comma) to be compatible with
PDx-Pop (and still fully NONMEM compatible)). 

C,Data Desc: tarun,,,,,
C,ID,VOL,TIME,DV,AMT,CMT
,1,91.825,0,.,3000000,1
,1,91.825,0,.,43916,3
,1,91.825,0,43916,.,3
,1,91.825,168,.,3000000,1
,1,91.825,168,16638,.,3
,1,91.825,336,.,3000000,1
,1,91.825,336,3349,.,3
,1,91.825,504,.,3000000,1
,1,91.825,504,6183,.,3
,1,91.825,672,.,3000000,1
,1,91.825,672,5707,.,3

the control stream:

You do need to use ERR(1) for an individual.  I assume that you will input
each individuals PK parameters via the data file when you move to the
population model (unless there is VERY LITTLE PK variability). The "F3"
statement was not needed.
(There is a value in starting with an individual model, it starts off simple
and you can simulate the individual to see if your initial estimates are in
the ballpark.  In fact, I would simulate full profiles to assure you are
getting the "shape" you anticipate, your data are all trough measurements.)
 
$PROB POP PK/PD Model  $DES
$INPUT C ID VOL TIME DV AMT CMT 
$DATA mydata.csv IGNORE=C
$SUBROUTINE ADVAN8 TRANS=1 TOL=3
$MODEL NCOMP=3
  COMP=(GUT)
  COMP=(CENTRAL)
  COMP=(EFFECT)
$PK
 KA=0.042
 KE=0.022
 V2=VOL
 S2=V2
 
 IC50=THETA(1);*EXP(ETA(1))
 KOUT=THETA(2);*EXP(ETA(3))
 KIN =THETA(3);*EXP(ETA(2))
 ;F3=KIN/KOUT  
$DES
 DADT(1)=-KA*A(1)
 DADT(2)=KA*A(1)-KE*A(2)
 CE=A(2)/V2
 DRUG1=1-CE/(CE+IC50)
 DADT(3)=KIN*DRUG1-KOUT*A(3)
$THETA 
(0, 497)   ;IC50
(0, 0.008)  ;KOUT
(0, 353)  ;KIN
$OMEGA
0.4
$ERROR
Y=F+ERR(1)
IPRED=F
$EST MAXEVAL=1000 PRINT=5
$TABLE ID TIME CMT FILE=T2.TAB



*******

From:"Sam Liao"   
Subject:RE: [NMusers] PK/PD problem using ADVAN6 [GM000245]  
Date:Fri, March 1, 2002 6:24 pm  



Hi Bill:

I think the original approach Tarun used is fine too.  The baseline
observation also subject to measurement error.  This issue has been
discussed previously.
==================================
File Name:99oct052000.html
Subject: PD initialization
Posting: October 5, 2000

12 occurence(s) of the search term liao

Subject: RE: PD initialization Date: Fri, 6 Oct 2000 09:43:37 -0400 Atul: I
agree with Vladimir, the AMT for CMT=2 dosing event record should be 1. I
would also suggest to use $SIMULATION to verify this. Sam
============================ liao & liao Consultants, Inc 270 Kerry Lane
Blue Bell, PA 19422 215-6541151 fax 2156540922 shliao@aol.com ***** From:
"Bachman, William"  Subject: RE: PD initialization
Date: Fri, 6 Oct 2000 09
======================================

Best regards,



Sam Liao, Ph.D.
PharMax Research
270 Kerry Lane,
Blue Bell, PA 19422
phone: 215-6541151
efax: 1-720-2946783