From: Garry Boswell" GBoswell@pcyc.com
Subject: [NMusers] Combined tissue and plasma concentration models  
Date: Mon, March 29, 2004 8:39 pm

All,
 
I have plasma, liver, kidney, and tumor concentration data
from single and multiple dose IV administration of a drug to
groups of mice.  I would like to develop a single NONMEM model
that I can use for predictive purposes to estimate concentrations
in theses matrices.  I can fit the data to separate models
successfully but I would like to use a single model.  Is this
possible and are there any references for such a model?

Garry Boswell 

_______________________________________________________

From: Nick Holford n.holford@auckland.ac.nz
Subject: RE:[NMusers] Combined tissue and plasma concentration models
Date: Mon, March 29, 2004 11:04 pm 

Garry, 

There is no reason in principle why you should not be able to specify a model for 4
matrices. The most straightforward method would be to code a set of differential
equations defining a mammillary model (e.g. using ADVAN6). If the model is all first
order then you can specify the model in a somewhat more abstract way using ADVAN7 or
ADVAN5.

In practice you may find it harder to fit all the data as well to a single connected
model as you did with separate models. Fitting the data simultaneously is a good
stress test for the validity of the assumptions made about how the observed
concentrations are related to each other.

Nick
--
Nick Holford, Dept Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
email:n.holford@auckland.ac.nz tel:+64(9)373-7599x86730 fax:373-7556
http://www.health.auckland.ac.nz/pharmacology/staff/nholford/


_______________________________________________________

From: musor000@optonline.net  
Subject: RE:[NMusers] Combined tissue and plasma concentration models
Date: Tue, March 30, 2004 9:18 pm  

Garry,

Your question is very general.  General answer is yes.  Here is a more specific
answer.  Here a model based on PK6 example by Gabrielsson (analytical model and
similar differential equation model).  

$PROBLEM  PK6 - one subject, IV and oral dosing. 
$INPUT      TIME CP=DV EXPE DOSE=AMT EVID CMT PCMT
  ;EXPE-EXPERIMENT: 
    ;1-BOLUS DOSE & BLOOD SAMPLE.
    ;2-BOLUS DOSE & URINE SAMPLE.
    ;3-ORAL DOSE  & BLOOD SAMPLE.
    ;4-ORAL DOSE  & URINE SAMPLE.
  ;CMT:  1-MOUTH, 2-BLOOD.
  ;PCMT: 2-BLOOD, 3-URINE.
  ;EVID: 0-OBSERVATION, 1-DOSE, 4-DOSE & RESET.
$DATA PK06DIF0.DA ;IGNORE #
$SUBROUTINES  ADVAN6  TOL=3    
  ;TOL - THE NUMBER OF ACCURATE DIGITS
$MODEL COMP=(DEPOT, INITIALOFF) 
       COMP=(CENTRAL) 
       COMP=(PERIPH,NODOSE)
$EST     MAXEVAL=9999 SIG=5 NOABORT PRINT=10 


$THETA
  (50,250,900)    ;VD -VOLUME OF DISTRIBUTION
  (.1,5,15)       ;CLE-CLEARENCE
  (.1,0.9,2)      ;BIO-BIOAVAILABILITY
  (.05,0.5,5)     ;KA -ABSORBTION COEFFICIENT
  (0.01,0.3,5)    ;TL -TIME LAG FOR ORAL DOSE
  (.01,0.08,2)    ;FE -FRACTION EXCRETED VIA URINE

  ;(287,287,287)           ;VD -VOLUME OF DISTRIBUTION
  ;(5.76,5.76,5.76)        ;CLE-CLEARENCE
  ;(1.09,1.09,1.09)        ;BIO-BIOAVAILABILITY
  ;(0.437,0.437,0.437)     ;KA -ABSORBTION COEFFICIENT
  ;(0.351,0.351,0.351)     ;TL -TIME LAG FOR ORAL DOSE
  ;(0.0741,0.0741,0.0741)  ;FE -FRACTION EXCRETED VIA URINE

;$OMEGA DIAGONAL(2) 20 10  ;CORR MATRIX OF ERRORS
$OMEGA 10  ;CORR MATRIX OF ERRORS
  ;NOTE: THERE ARE TOO MANY PARAMETERS IN THE MODEL.
  ;IF OMEGA HAS 2 ELEMENTS, THEN MOREL DOES NOT CONVERGE
  ;DUE TO ROUNDING ERRORS.

$COV 



$PK
  VD =THETA(1)
  CLE=THETA(2)
  BIO=THETA(3)
  KA =THETA(4)
  ALAG1 =THETA(5)
  IF (EXPE.LE.2) ALAG1=0 ;TIME LAG EXIST FOR ORAL DOSE ONLY
  FE =THETA(6)
  KE = CLE/VD
  IND=1                ;INDICATOR OF ORAL DOSE
  IF (EXPE.LE.2) IND=0   
  S2=VD                ;The amount A in the observation compartment
                       ;at the time of observation, divided by the 
                       ;value of a parameter S, is used as the prediction. 
  ;CALL INFN(ICALL,THETA,DATREC,INDXS,NEWIND)


$DES
  DADT(1)=-KA*A(1)*IND
  DADT(2)=-CLE/VD*A(2)+BIO*KA*A(1)*IND
  DADT(3)=FE*CLE/VD*A(2)
  A1=A(1)
  A2S=A(2)/VD
  A2=A(2)
  A3=A(3)

$ERROR
  CONC=F
  IF (EXPE.EQ.1.OR.EXPE.EQ.3) Y=CONC*(1+ETA(1))  ;CONCENTRATION ERROR
  IF (EXPE.EQ.2.OR.EXPE.EQ.4) Y=CONC*(1+ETA(1))  ;URINE AMT ERROR
    IPRE=CONC      ;  individual-specific prediction
    IRES=DV-IPRE   ;  individual-specific residual
    IWRE=IRES/CONC ;  individual-specific weighted residual
  ;CALL INFN(ICALL,THETA,DATREC,INDXS,NEWIND)
                    

   
;$TABLE KE STH2 W   FIRSTONLY NOAPPEND
$TABLE TIME DOSE PRED CMT PCMT A1 A2 A2S A3
$SCAT  DV VS IPRE UNIT BY EXPE
$SCAT  PRED VS TIME BY EXPE
$SCAT  (IRES IWRE) VS TIME BY EXPE

0       .         1  12000  4 2 2
0.333   47.5      1      .  0 2 2
0.6667  46.2      1      .  0 2 2
1       46.5      1      .  0 2 2
2.0   42.9        1      .  0 2 2
3.0   45.9        1      .  0 2 2
4.0   44.8        1      .  0 2 2
6.0   40.5        1      .  0 2 2
8.0   38.0        1      .  0 2 2
24.0  26.3        1      .  0 2 2
24.0  340         2      .  0 3 3
48.0  14.2        1      .  0 2 2
48.0  550         2      .  0 3 3
72.0   8.8        1      .  0 2 2
96.0   5.7        1      .  0 2 2
168.0  1.5        1      .  0 2 2
0       .         3  25000  4 1 2
0.333  0.94       3      .  0 2 2
0.6667 13.1       3      .  0 2 2
1      27.9       3      .  0 2 2
2.0    38.0       3      .  0 2 2
3.0    71.9       3      .  0 2 2
4.0    76.1       3      .  0 2 2
6.0    83.9       3      .  0 2 2
8.0    75.0       3      .  0 2 2
24.0   51.6       3      .  0 2 2
24.0   705        4      .  0 3 3
48.0   34.9       3      .  0 2 2
48.0  1210        4      .  0 3 3
72.0   23.4       3      .  0 2 2
96.0   14.5       3      .  0 2 2
168.0   4.5       3      .  0 2 2
* ****************************************************;
$PROBLEM  PK6 - one subject, IV and oral dosing. 
$INPUT      TIME CP=DV EXPE DO
$DATA PK06ANA1.DA ;IGNORE #
$EST     MAXEVAL=9990 SIG=7 PRINT=5
$COV

$THETA
  (.001,300,1000) ;VD
  (.001,5,20)     ;CLE
  (.001,0.9,5)    ;BIO
  (.001,1.0,5)    ;KA
  (.001,0.2,5)    ;TL
  (.001,0.2,5)    ;FE

$OMEGA DIAGONAL(2) 30 50  ;NEDIAGONALNAYA CORR MATRITSA

$PRED
  VD =THETA(1)
  CLE=THETA(2)
  BIO=THETA(3)
  KA =THETA(4)
  TL =THETA(5)
  FE =THETA(6)
  KE = CLE/VD
  IF (EXPE.EQ.1) THEN
    DIV=DO
    F = (DIV/VD)*EXP(-(CLE/VD)*TIME)
    Y=F+ETA(1)
  ENDIF
  IF (EXPE.EQ.2) THEN
    DPO=DO
    F = ((BIO*DPO*KA)/(VD*(KA-KE)))*(EXP(-KE*(TIME-TL))-EXP(-KA*(TIME-TL))) 
    Y=F+ETA(1)
  ENDIF    
  IF (EXPE.EQ.3) THEN
    DIV=DO
    F = FE*DIV*(1. - EXP(-(CLE/VD)*TIME))
    Y=F+ETA(2)
  ENDIF
  IF (EXPE.EQ.4) THEN
    DPO=DO
    REST = (CLE/VD)*EXP(-KA*(TIME-TL))/(KA*(CLE/VD - KA))
    F=FE*KA*BIO*DPO*(1/KA+EXP((-CLE/VD)*(TIME-TL))/(CLE/VD-KA)-REST)
    Y=F+ETA(2)
  ENDIF
       IPRED=F         ;  individual-specific prediction
       IRES=DV-IPRED   ;  individual-specific residual
       IWRES=IRES/F    ;  individual-specific weighted residual

   
$TABLE EXPE TIME DO PRED DV RES WRES
$SCAT  DV VS IPRED UNIT BY EXPE

0.333   47.5    1  12000    
0.6667  46.2    1  12000      
1       46.5    1  12000      
2.0   42.9      1  12000      
3.0   45.9      1  12000      
4.0   44.8      1  12000      
6.0   40.5      1  12000      
8.0   38.0      1  12000      
24.0   26.3     1  12000      
48.0   14.2     1  12000      
72.0   8.8      1  12000      
96.0   5.7      1  12000      
168.0  1.5      1  12000      
0.333  0.94     2  25000      
0.6667 13.1     2  25000      
1      27.9     2  25000      
2.0    38.0     2  25000      
3.0    71.9     2  25000      
4.0    76.1     2  25000      
6.0    83.9     2  25000      
8.0    75.0     2  25000      
24.0   51.6     2  25000      
48.0   34.9     2  25000      
72.0   23.4     2  25000      
96.0   14.5     2  25000      
168.0  4.5      2  25000      
24.0    340     3  12000
48.0    550     3  12000
24.0    705     4  25000
48.0    1210    4  25000

_______________________________________________________