```From: Garry Boswell
Subject:[NMusers] Using covariates with positive and negative values
Date:  Mon, 5 May 2003 08:51:28 -0700

NONMEM GROUP,

I have data from a mouse TK study that I am attempting to analyze using NONMEM.  Mice
were administered IP doses of a drug and single blood samples/animal were obtained at
serial time points.  Both single dose and multiple dose (steady state) data were obtained.  I
have LN transformed DV and have been successful at fitting the data using ADVAN2
TRANS2 and the control stream below:

\$PROB ETA ON CL and V Sex on V
\$INPUT   ID DATE=DROP TIME ODV DV AMT MDV EVID CMT SS II Grp Sex Wt
\$DATA   COMBINED_LN_MOD.CSV IGNORE=c
\$PK
TVCL = THETA(1)
TVV=THETA(2)+Sex*THETA(4)
TVKA = THETA(3)
CL=TVCL +EXP(ETA(1))
V=TVV + EXP(ETA(2))
KA=TVKA
K = CL/V
Half= (0.693/K)
S2 = V
\$ERROR
PRD=F
IPRED=0
IF(F.GT.0) IPRED=LOG(F)
Y=IPRED + EPS(1)
IWRE=0
IRES=DV-IPRED
IF(IPRED.NE.0) IWRE=IRES/IPRED
\$THETA (0, 2)  (0, 30) (0, 6)  (1) (1)
\$OMEGA  0.6, 0.1
\$SIGMA  0.1
\$EST  MAXEVALS = 3000
SIGDIGITS =4  PRINT = 10  POSTHOC
METHOD=CONDITIONAL
\$COV CONDITIONAL
\$TABLE  NOPRINT
ID Grp Sex TIME CL V KA Half K
IPRED IRES IWRE PRD ODV PRED RES WRES

However when I try to include a covariate for weight change on either V or CL, the
parameter goes negative and causes NONMEM to halt execution.  This occurs with weight
change added as either an additive or portortional covariate.  I did not LN transform
the weight data since both positive and negative changes were allowed.  Would someone
with experience with this type of problem offer a suggestion?

Garry Boswell, Ph.D.
Senior Director,  Pharmaceutical Development
Pharmacyclics, Inc.
995 Arques Avenue
Sunnyvale, CA 95085
(408) 328-3635
E-mail: gboswell@pcyc.com

_______________________________________________________

From: "Bhattaram, Atul"
Subject: RE: [NMusers] Using covariates with positive and negative values
Date:Mon, 5 May 2003 12:08:48 -0400

Hello Garry

Did you try a power model or an exponential model? This should take care of the
positive and negative changes.

Venkatesh Atul Bhattaram
CDER, FDA.
_______________________________________________________

From:"Bachman, William"
Subject:RE: [NMusers] Using covariates with positive and negative values
Date:  Mon, 5 May 2003 12:34:07 -0400

couple of observations:

1. do you really want to add an exponential term or multiply by the exponential term:
CL=TVCL *EXP(ETA(1))
V=TVV* EXP(ETA(2))
2. in the absence of a meaningful estimate of the covariate effect, I suggest using a
small value to only minimally perturb the system from the base model, e.g
your theta(4) and theta(5) are large and causing the parameters to go negative.
Try something like 0.001 instead of  1 for their estimates and use the final
estimates from your base model for the other parameter estimates.  That way
you start off no worse than the base model.

3. Once you get your model to at least begin to iterate, you can use NOABORT on the \$EST
record to let the minimization proceed in the presence of negative parameters.

nmconsult@globomaxnm.com
GloboMax LLC
7250 Parkway Drive, Suite 430
Hanover, MD 21076
Voice: (410) 782-2205
FAX: (410) 712-0737
_______________________________________________________

From:  Leonid Gibiansky
Subject: Re: [NMusers] Using covariates with positive and negative values
Date:Mon, 05 May 2003 12:35:25 -0400

Garry,
The model that you used is incorrect, you should not use
CL=TVCL +EXP(ETA(1)).
Use
CL=TVCL*EXP(ETA(1))
(or  CL=TVCL+ETA(1)     ).
To account for weight covariate, use something like
CL=TVCL*EXP( THETA(?)*(WT/WT0-1)+ETA(1))
where WT0 is the mean or median weight, and similarly for V.
Also, with just one point per animal, you may have problems with you model
since you will have three parameter per animal (two eta's and one sigma) to
fit just one data point. If your sampling points are at fixed time relative
to the dose, I would rather try simple concentration versus covariate model
C(fixed time, the same for all animals) = A+B*sex + C*(WT/WT0-1).
If not, you may try to remove random effect from either volume or clearance
and see how this will affect the result (covariate can be added to the
parameter even if there are no random effect on this parameter).

Leonid
_______________________________________________________

From: Nick Holford
Subject:Re: [NMusers] Using covariates with positive and negative values
Date:Tue, 06 May 2003 08:17:57 +1200

Garry,

The example you show of SEX as a covariate (and the verbal description of using WT)
indicate that you are using an additive covariate model e.g.

IF (SEX.EQ.1) THEN
CLSEX=THETA(male)
ELSE
CLSEX=0
ENDIF
CLWT=THETA(wt)*WT
CLREST=THET(rest) ; the rest of the clearance not predicted by SEX or WT
TVCL = CLREST + CLSEX + CLWT

As you have noticed it is quite possible to get problems with negative values for CL with
this model. Even if you avoid this during estimation it can be possible to apply your
final model with WT outside the original range and predict negagive CL. Sometimes these
models even get published! Note you could easily get a negative estimate for CLREST which
emphasizes its non-biological meaning.

I prefer to use multiplicative models for covariate effects. This makes it easy to
describe the relative importance of each covariate, can be readily written to prevent
negative values and allows a convenient way to combine several covariate effects e.g.

; FSEX, FWT and FAGE are the fractional changes in CL due to each covariate
; e.g. if FSEX is 1.2 if would mean that CL was 20% higher in men compared with women
IF (SEX.EQ.1) THEN
FSEX=THETA(male)
ELSE
FSEX=1
ENDIF
FWT=(WT/70)**0.75 ; allometric model centered on 70 kg
FAGE=EXP(THETA(age)*(AGE-40)) ; empirical age effect centered on 40 y

TVCL = CLSTD*FSEX*FWT*FAGE

The empirical EXP() model I show for modelling the effect of AGE can be used with any
continuous covariate. It has the property of preventing non-positive typical values for
parameters like CL. When the covariate effects are small (and they typically are) then
the EXP() model approximates a linear model:
FAGE=1+THETA(age)*(AGE-40) ; approx EXP(x) when x is small
The parameter THETA(age) is easily interpreted as the fractional change in CL per unit
change in AGE.

Note that I refer to the population estimate of CL as CLSTD. This is a reminder that it
will be the CL in a standard individual. In this case a 70 kg, 40 year old female.

The only time I would deliberately use an additive rather than a multiplicative model for
a covariate effect is when the biology clearly pointed this way. An example is the
additive nature of renal and non-renal clearance. I know that these components of CL are

TVCL = CLnr + RF*CLr

where RF is renal function. I compute RF=CLcr/CLcrstd where CLcr is an estimate of
creatinine clearance (e.g. obtained from Cockcroft&Gault using serum creatinine) and
CLcrstd is CLcr in my standard individual e.g. 6 L/h/70kg.

I would include other covariates multiplicatively e.g.

TVCL = (CLnr*FSEX*FAGE  + RF*CLr)*FWT

This says I suspect a sex and age effect on non-renal CL (but not on renal CL) and I
expect WT to affect both non-renal and renal clearance.

Leonid has already pointed out the EXP() model although I would not use it for WT because
I know the allometric model has much stronger biological support. He has also suggested
that it would be more usual to express the random effects with an EXP() model:

CL=TVCL*EXP(ETA(cl))

The model you were using would have forced all the random effects to be positive and so
your TVCL value would necessarily become less than the lowest actual individual CL.

Nick
--
Nick Holford, Dept Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
email:n.holford@auckland.ac.nz tel:+64(9)373-7599x86730 fax:373-7556

http://www.health.auckland.ac.nz/pharmacology/staff/nholford/

_______________________________________________________

```