From: "Yungwei Hsu" <hsu00013@mc.duke.edu>
Subject: [NMusers] 3 compartment nonlinear pharmacokinetics model
Date: Tue, 13 Nov 2001 14:57:35 -0500

Dear all,

I am trying to model a 3 compartment nonlinear PK model. The drug's
elimination rate is concentration-dependent. Increasing concentration
decreases the clearance. My experiment is based on a computer controlled
infusion program to target plasma concentration at 4 different steady state
levels, each level last 40 min. Two pk data were collected in each step and
also series of recovery pk data were collected.

Could somebody provide me a template of control file to model this problem?

Thanks,

Yung-Wei Hsu
Human Pharmacology Laboratory
Duke University Medical Center
e-mail: hsu00013@mc.duke.edu

 

 

*****

 

 

From: Nick Holford <n.holford@auckland.ac.nz>
Subject: Re: [NMusers] 3 compartment nonlinear pharmacokinetics model
Date: Wed, 14 Nov 2001 09:47:29 +1300

Yungwei Hsu wrote:
>
> Dear all,
>
> I am trying to model a 3 compartment nonlinear PK model. The drug's
> elimination rate is concentration-dependent. Increasing concentration
> decreases the clearance. My experiment is based on a computer controlled
> infusion program to target plasma concentration at 4 different steady state
> levels, each level last 40 min. Two pk data were collected in each step and
> also series of recovery pk data were collected.
>
> Could somebody provide me a template of control file to model this problem?

Assuming you know how to set up the data file for a linear PK problem then you can use the same data format. The model code could look like the following. Note that PREDPP will take care of the input into compartment one. You should not add a term to the DADT(1) expression for the infusion input. Also because of an NONMEM naming convention you cannot use the same variable name in $DES and $ERROR which is why I use DC1 in $DES and C1 in $ERROR.

$SUBR ADVAN6 TOL=5
$MODEL
COMP (ONE)
COMP (TWO)
COMP (THREE)
$PK
V1=THETA()*EXP(ETA())
VMAX=THETA()*EXP(ETA())
KM=THETA()*EXP(ETA())
V2=THETA()*EXP(ETA())
Q2=THETA()*EXP(ETA())
V3=THETA()*EXP(ETA())
Q3=THETA()*EXP(ETA())
$DES
DC1=A(1)/V1
DC2=A(2)/V2
DC3=A(3)/V3
CL=VMAX/(KM+DC1)
DADT(1)=Q2*DC2 + Q3*DC3 - (Q2 + Q3 + CL) *DC1
DADT(2)=Q2*(DC1-DC2)
DADT(3)=Q3*(DC1-DC3)
$ERROR
C1=A(1)/V1
Y=C1*EXP(ERR()) + ERR()

Your data set seems VERY sparse so dont expect too much from trying to fit this model.

Nick
--
Nick Holford, Divn Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
email:n.holford@auckland.ac.nz tel:+64(9)373-7599x6730 fax:373-7556
http://www.health.auckland.ac.nz/pharmacology/staff/nholford/

 

 

*****

 

 

From: "Yungwei Hsu" <hsu00013@mc.duke.edu>
Subject: Re: [NMusers] 3 compartment nonlinear pharmacokinetics model
Date: Wed, 14 Nov 2001 17:08:02 -0500

Dear Dr. Holford,

Thank you very much for your generous help.
After running the NONMEM, I got

V1 V max Km V2 CL2 V3 CL3

5.83 1.17 0.746 121 0.630 37 1.23

and the following message
======================================
MINIMIZATION SUCCESSFUL
NO. OF FUNCTION EVALUATIONS USED: 1038
NO. OF SIG. DIGITS IN FINAL EST.: 3.1
S MATRIX ALGORITHMICALLY SINGULAR
T MATRIX SET EQUAL TO RS*R, WHERE S* IS A PSEUDO INVERSE OF S
===================================================================

What does this means? My control file is as follows,

==========================================
$PROBLEM 3 COMPARTMENT Nonlinear Kinetics Modeling
$INPUT ID TIME AMT=DOSE CONC=DV RATE
$DATA input10
$SUBROUTINES ADVAN6 TOL=5
$MODEL COMP (ONE) COMP (TWO) COMP (THREE)
$PK
V1=THETA(1)*EXP(ETA(1))
VMAX=THETA(2)*EXP(ETA(2))
KM=THETA(3)*EXP(ETA(3))
V2=THETA(4)*EXP(ETA(4))
Q2=THETA(5)*EXP(ETA(5))
V3=THETA(6)*EXP(ETA(6))
Q3=THETA(7)*EXP(ETA(7))
$DES
DC1=A(1)/V1
DC2=A(2)/V2
DC3=A(3)/V3
CL=VMAX/(KM+DC1)
DADT(1)=Q2*DC2 + Q3*DC3 - (Q2 + Q3 + CL) *DC1
DADT(2)=Q2*(DC1-DC2)
DADT(3)=Q3*(DC1-DC3)
$ERROR
C1=A(1)/V1
Y=C1*EXP(ERR(1)) + ERR(2)

$THETA
7.41
1.79
1.95
27.7
1.14
115
0.8
$OMEGA1 0.1 0.1 5 0.1 2 0.1
$SIGMA 0.1 0.1
$COVAR UNCONDITIONAL
$EST SIG=3 MAX=3000 PRINT=5 NOABORT METHOD=0
;$MSFI=ms2 POPETAS=6
=======================================================

Is there something wrong with my control file?

Yung-Wei Hsu

 

 

*****

 

 

From: Nick Holford <n.holford@auckland.ac.nz>
Subject: Re: [NMusers] 3 compartment nonlinear pharmacokinetics model
Date: Thu, 15 Nov 2001 13:09:44 +1300

Yungwei Hsu wrote:
>
> Dear Dr. Holford,
>
> Thank you very much for your generous help.
> After running the NONMEM, I got
>
> V1 V max Km V2 CL2
> V3 CL3
>
> 5.83 1.17 0.746 121 0.630
> 37 1.23
>
> and the following message
> ======================================
> MINIMIZATION SUCCESSFUL
> NO. OF FUNCTION EVALUATIONS USED: 1038
> NO. OF SIG. DIGITS IN FINAL EST.: 3.1
> S MATRIX ALGORITHMICALLY SINGULAR
> T MATRIX SET EQUAL TO RS*R, WHERE S* IS A PSEUDO INVERSE OF S
> ===================================================================
> What does this means? My control file is as follows,

It means you were very lucky!! Most of the time NONMEM has trouble computing the COVARIANCE step but by some trickery it can get a reasonably close approximation. That is what the messages about the various matrices are about.

--
Nick Holford, Divn Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
email:n.holford@auckland.ac.nz tel:+64(9)373-7599x6730 fax:373-7556
http://www.health.auckland.ac.nz/pharmacology/staff/nholford/