From: bvatul <bvatul@ufl.edu>
Subject: PD initialization
Date: Thu, 05 Oct 2000 19:10:51 -0400

Dear NMusers,

I am trying to PK/PD model a data set where the PD is explained by an indirect response model with the production of the endogenous substance suppressed by the drug.

$DES
DADT(1)=-K*A(1) ; PK
CP=A(1)/S1
EFF=1-CP/(CP+EC50)
DADT(2)=K0*EFF-KE*A(2) ; PD

The value of the PD parameter is 10 ng/ml in the absence of the drug. i.e at time zero. In the DV column, I put DV=10 with CMT=2.

When we fit the data, why is it that the PD value at time zero starts at zero instead of 10?

I looked into page 331 in the help guide. It says that i should initialize the system with a bolus dose into the PD compartment. I dont exactly understand what is intended?

Comments/ suggestions are appreciated.

Thanks
Atul


*****


From: "Piotrovskij, Vladimir [JanBe]" <VPIOTROV@janbe.jnj.com>
Subject: RE: PD initialization
Date: Fri, 6 Oct 2000 13:23:17 +0200

Atul,

The NONMEM users guide is rather vague as usual. What you have to do is initializing CMT 2 by putting a dummy AMT equal to 1 at time 0. Then you should pass the baseline level of A(2) (which is K0/KE) to $DES via F2:

$PK
...
F2 = K0/KE

Hope this helps.

Best regards,
Vladimir
----------------------------------------------------------------------
Vladimir Piotrovsky, Ph.D.
Janssen Research Foundation
Human Pharmacokinetics (ext. 5463)
B-2340 Beerse
Belgium
Email: vpiotrov@janbe.jnj.com


*****


From: "Bachman, William" <bachmanw@globomax.com>
Subject: RE: PD initialization
Date: Fri, 6 Oct 2000 08:02:55 -0400

Atul,

What Vladimir is telling you to do is essentially to define the initials condition for your differential equation for cmt=2 by putting a value in the AMT column (not in DV). However, unless there is a scaling factor you did not specify, I believe that amount should be 10 (not 1).

regards,
Bill

William J. Bachman, Ph.D.
Senior Scientist
GloboMax LLC
7250 Parkway Drive, Suite 430
Hanover, MD 21076
Telephone: (410) 782-2212
FAX: (410) 712-0737


*****


From: "Jogarao Gobburu 301-594-5354 FAX 301-480-3212" <GOBBURUJ@cder.fda.gov>
Subject: Re: PD initialization
Date: Fri, 06 Oct 2000 08:55:59 -0400 (EDT)

Hello,
1. Another way to code this is to include SS data item(=1 for CMT=2,else =0 if pk is not at steady-state) to specify that PD is at steady-state before dosing. You have to provide another data record for your 'observation', as you do with most PK problems. AMT=0 indicates steady-state with constant rate infusion (see help guide 'AMT').

eg: #ID TIME AMT SS CMT DV ...
1 0 0 1 2 .
1 0 . 0 2 10
1 0 100 0 1 .

2. You might want to consider re-parameterizing your equation in terms of CL (and V) rather than k, if applicable.

Regards,
Joga Gobburu
Pharmacometrics,
CDER, FDA.


*****


From: "Liao, Sam [PRI]" <SLIAO@prius.jnj.com>
Subject: RE: PD initialization
Date: Fri, 6 Oct 2000 09:43:37 -0400

Atul:

I agree with Vladimir, the AMT for CMT=2 dosing event record should be 1.

I would also suggest to use $SIMULATION to verify this.

Sam
============================
Liao & Liao Consultants, Inc
270 Kerry Lane
Blue Bell, PA 19422
215-6541151
fax 2156540922
shliao@aol.com


*****


From: "Bachman, William" <bachmanw@globomax.com>
Subject: RE: PD initialization
Date: Fri, 6 Oct 2000 09:50:09 -0400

Hi, Sam

You might agree - but you'd be wrong! :)

You are not fitting EFF, you are fitting and defining the initial condition for the response variable - in this case a concentration that has a baseline value of 10 not 1. The other alternative is as Joga suggested defining a steady state infusion to establish the baseline response.


regards,
Bill


*****


From: "Liao, Sam [PRI]" <SLIAO@prius.jnj.com>
Subject: RE: PD initialization
Date: Fri, 6 Oct 2000 10:21:12 -0400

Bill:

I guess we have different objectives. In my study, the baseline values are also considered an experimental measurements that subject to error.


*****


From: "nelamangala nagaraja" <nvnagaraj@hotmail.com>
Subject: RE: PD initialization
Date: Fri, 06 Oct 2000 12:57:45 EDT

Hi all,
The suggestion by Dr.Piotrovskij is that we add an AMT data at time=0 for initializing the PD parameter. In fact myself and Atul were attempting the same way and it has a bug in it. It does not FIT the PD data at time=0. Instead, if we give a value of (say) 3.5 (which is actually the concentration at t=0) as the AMT, the PRED will be 3.5 (at t=0). In the second subject, if we give 4.5 as AMT, PRED will return as 4.5. Is there any alternative way of fitting E0?

Raj

Nelamangala V. Nagaraja, PhD
Post Doc Res Assoc
Department of Pharmaceutics,
University of Florida,
Gainesville, FL-32610
Ph: 352-846-3257
Fax: 352-392-4447


*****


From: Sriram Krishnaswami <ksriram@ufl.edu>
Subject: PD initialization
Date: Mon, 09 Oct 2000 14:53:39 +1000

Hello,

We tried another way to solve this problem.

Without putting AMT=1 at t=0 or making any changes/additions to the control stream, or adding SS to the data file, we tried the following with the data file.

Just add two records for each subject (for ex. time 0 and time 12 with DVs=0 and MDVs=1) and shift the whole analysis by say 24 hours. i.e the drug dose is given at 24 hours. E0 is the observed DV value at 24 hours. In this case the PD value starts at zero at time 0 and increases with time until it reaches steady state. In other words, we allow sufficient time for the PD to reach steady state before the drug is administered.

This method seems to work just fine.

Any suggestions on its validity?

Thanks
Sriram

Sriram Krishnaswami
Graduate student
Dept. of Pharmaceutics
College of Pharmacy
University of Florida
Gainesville, FL 32610-0494
Home: 352 846 5968
Lab: 352 846 3257
Fax: 352 392 4447


*****


From: "Piotrovskij, Vladimir [JanBe]" <VPIOTROV@janbe.jnj.com>
Subject: RE: PD initialization
Date: Mon, 9 Oct 2000 11:25:36 +0200

The control and the simulated data set below illustrate my point. It works perfectly in the estimation mode. It is a single-individual example which can easily be generalized for the population case.

Unexpectedly, the situation turned out to be not so simple. When the control below is run in a simulation mode it produces biased PRED at TIME = 0 for both compartments 1 and 2. Nevertheless, if OMEGAs are fixed to 0 there is no bias in PRED anymore. It seems to be a bug. I will explore this further and will post a question to nmconsult.

Best regards,
Vladimir

----------------------------------------------------------------------
NM-TRAN Control stream

$PROBLEM PK-PD simultaneous
$INPUT ID TIME DV AMT CMT
$DATA nmd.ssc
$SUB ADVAN9 TOL=6
$MODEL
COMP=(CENTRAL)
COMP=(EFFECT)
$PK
K = THETA(1)
EC50 = THETA(2)
K0 = THETA(3)
KE = THETA(4)
S1 = THETA(5)
F2 = K0/KE
$DES
DADT(1)=-K*A(1) ; PK
CP = A(1)/S1
EFF = 1-CP/(CP+EC50)
DADT(2)= K0*EFF - KE*A(2) ; PD
$ERROR
IF (CMT.EQ.1) THEN
Y = F * EXP(ERR(1))
ELSE
Y = F * EXP(ERR(2))
ENDIF
$THETA
(0 0.5 1); 1 K
(0 0.5 2); 2 EC50
(0 1.0 5); 3 K0
(0 0.1 1); 4 KE
(0 20.0 100); 5 S1
$OMEGA .02 .05
;$SIM (51813)
$EST PRINT=10 MAX=9990
$COV
$TABLE ID TIME AMT CMT
FILE=tab.ssc NOPRINT ONEHEADER


Data set

1 0 0 100 1
1 0 0 1 2
1 0 4.74 0 1
1 0 11.04 0 2
1 1 3.0668 0 1
1 1 8.5346 0 2
1 2 1.9344 0 1
1 2 6.6172 0 2
1 3 1.0375 0 1
1 3 9.0932 0 2
1 4 0.56123 0 1
1 4 9.3156 0 2
1 5 0.44249 0 1
1 5 7.8811 0 2
1 6 0.21302 0 1
1 6 5.78 0 2
1 7 0.15583 0 1
1 7 7.0446 0 2
1 8 0.083318 0 1
1 8 7.7035 0 2
1 9 0.047182 0 1
1 9 5.8446 0 2
1 10 0.033686 0 1
1 10 7.3329 0 2


*****


From: "Piotrovskij, Vladimir [JanBe]" <VPIOTROV@janbe.jnj.com>
Subject: RE: PD initialization
Date: Mon, 9 Oct 2000 13:15:02 +0200

Sorry, I was wrong. No bug at all. The control stream works fine also for simulations.
Vladimir


*****


From: ABoeckmann <alison@c255.ucsf.edu>
Subject: PD initialization
Date: Mon, 9 Oct 2000 10:05:41 -0700 (PDT)

There has been some discussion on how to initialize a baseline value for a PD compartment. I'll try to summarize what everyone has said on this. Basically, I agree with everyone. Different techniques were suggested, but they all can be used in this case.

Atul's original question:

> I am trying to PK/PD model a data set where the PD is explained by an
> indirect response model with the production of the endogenous substance
> suppressed by the drug.
>
> $DES
> DADT(1)=-K*A(1) ; PK
> CP=A(1)/S1
> EFF=1-CP/(CP+EC50)
> DADT(2)=K0*EFF-KE*A(2) ; PD
>
> The value of the PD parameter is 10 ng/ml in the absence of the drug.
> i.e at time zero
> In the DV column, I put DV=10 with CMT=2.
>
> When we fit the data, why is it that the PD value at time zero starts at
> zero instead of 10?
>
> I looked into page 331 in the help guide. It says that i should
> initialize the system with a bolus dose into the PD compartment.
> I don't exactly understand what is intended?

I don't know what he means by the "PD parameter". People seem to think he means "the amount in compartment 2".

Vladimir Piotrovsky and others suggested initializing CMT 2 by putting a dose record with AMT equal to 1 at time 0. In $PK, you must assign to F2 the baseline level of A(2). This causes PREDPP to multiply 1 by the the baseline level of A(2) when the "dose" is put into compartment 2.

F2 can be modeled in different ways. Vladimir suggests using the steady state solution to the D.E. DADT(2)=K0*EFF-KE*A(2)=0, which is (when DADT(2)=0 and EFF=1) A(2)=K0/KE. He suggests:

$PK
...
F2 = K0/KE

This seems quite correct.

Bill Bachman writes:

> What Vladimir is telling you to do is essentially to define the initials
> condition for your differential equation for cmt=2 by putting a value in the
> AMT column (not in DV). However, unless there is a scaling factor you did
> not specify, I believe that amount should be 10 (not 1).

Bill's suggestion (F2=10) is appropriate to Atul's original statement, if we assume that Atul wants to put exactly 10 in compartment 2.

Jogarao Gobburu writes:

> 1. Another way to code this is to include SS data item(=1 for
> CMT=2,else =0 if pk is not at steady-state) to specify that PD is at
> steady-state before dosing. You have to provide another data record for
> your 'observation', as you do with most PK problems. AMT=0 indicates
> steady-state with constant rate infusion (see help guide 'AMT').

eg: #ID TIME AMT SS CMT DV ...
1 0 0 1 2 .
1 0 . 0 2 10
1 0 100 0 1 .

This is not incorrect - this should give the same result as Vladimir's suggestion. A steady state does is appropriate when there is no easy analytic solution, e.g., when there are more than 1 compartments to be initialized. Here, it is not necessary and will take more computer time.

But now, Raj seems to want to do more:

> The suggestion by Dr.Piotrovskij is that we add an AMT data at
> time=0 for initializing the PD parameter. In fact myself and Atul
> were attempting the same way and it has a bug in it. It does not
> FIT the PD data at time=0. Instead, if we give a value of (say)
> 3.5 (which is actually the concentration at t=0) as the AMT, the
> PRED will be 3.5 (at t=0). In the second subject, if we give 4.5 as
> AMT, PRED will return as 4.5. Is there any alternative way of
> fitting E0?

Atun said the baseline amount in A(2) (the PD value) was known and was constant. Now, it appears to be different for each subject.

I think there are two ways to go. If the inter-subject difference is due to differences in K0 and/or KE, then
F2 = K0/KE
This allows NONMEM to estimate K0 and KE so to best fit both the baseline and the subsequent observations.

If the baseline varies according to unknown influences, then a theta could be introduced.
E.g.,
F2= THETA(x)
Let NONMEM estimate this theta.

Either way, each subject's data set needs both a dose record at time 0 (with CMT = 2 and AMT = 1), and an observation event record at time 0 (with CMT=2, DV= observed baseline value, e.g., 3.5 or 4.5), so that the baseline can be fit.

eg: #ID TIME AMT CMT DV ...
1 0 1 2 .
1 0 . 2 3.5
1 0 100 1 .


*****


From: "Jogarao Gobburu 301-594-5354 FAX 301-480-3212" <GOBBURUJ@cder.fda.gov>
Subject: Re: PD initialization
Date: Mon, 09 Oct 2000 13:39:52 -0400 (EDT)

Hello,
1. Should F2=THETA() be used, one should make sure that either Kin or Kout is reparameterized with respect to F2. For eg: Kout=THETA(1), F2=THETA(2) => Kin=Kout*F2.
2. I personally prefer to use inter-individual variability on Kin and Kout rather than the baseline value itself. This ensures more mechanistic interpretation of the results.

Regards,
Joga Gobburu
Pharmacometrics
CDER, FDA.


*****


From: "Liao, Sam [PRI]" <SLIAO@prius.jnj.com>
Subject: RE: PD initialization
Date: Mon, 9 Oct 2000 15:56:12 -0400

Sriram:

By your method, the time to reach the SS will depend on the Kout rate constant. In some cases, 24 hr may not be long enough to reach the SS. This may not be the best way to handle it.

Best regards,

Sam
============================
Liao & Liao Consultants, Inc
270 Kerry Lane
Blue Bell, PA 19422
215-6541151
fax 2156540922
shliao@aol.com


*****


From: ABoeckmann <alison@c255.ucsf.edu>
Subject: PD initialization
Date: Mon, 9 Oct 2000 13:48:09 -0700 (PDT)

Letting the system run long enough to reach steady state is a valid way of initializing it. Compt 2 should reach the same value as the other ways that have suggested for initializing with the steady state amount A(2)=K0/KE.