From: "HUTMACHER, MATTHEW" <MATTHEW.HUTMACHER@chi.monsanto.com>
Subject: Variance of the predictions of the etas.
Date: Wed, 22 Sep 1999 14:02:14 -0500

Hello all,

I was wondering if anyone knew an easy way to get NONMEM to output an estimate of the variance of the empirical Bayes predictions (the etas). To be more precise, let "cl_eta_i" be the true value of the variance component on clearance for individual i, let "p_cl_eta_i" be the empirical Bayes prediction for cl_eta_i. What I would like to calculate is VAR(p_cl_eta_i - cl_eta_i). Actually, in a more general sense, let "eta_i" be the vector of the true values of the variance components for individual i, and "p_eta_i" the prediction. Is there an easy way to get the matrix VAR(p_eta_i - eta_i)?

Thank you.

Matt

 

 

*****

 

 

Date: Wed, 22 Sep 1999 20:36:32 -0700
From: Lewis Sheiner <lewis@c255.ucsf.edu>
Subject: Re: Variance of the predictions of the etas.

No easy way, unfortunately. There's a hard way, but it's hard to describe in email - basically, treat each individual as a separate run and do a Bayesian estimate for each one conditional on the pop params, and ask for COV. Doing the Bayes estimate is the tricky part.

LBS.
--
Lewis B Sheiner
Professor, Lab. Med., Bioph. Sci, Med.
Box 0626 - UCSF
San Francisco, CA
94143
415-476-1965 (voice)
415-476-2796 (fax)
lewis@c255.ucsf.edu

 

 

*****

 

 

Date: Thu, 23 Sep 1999 08:31:06 -0700 (PDT)
From: ABoeckmann <alison@c255.ucsf.edu>
Subject: Re: Variance of the predictions of the etas.

RE: two recent emails:

Here is a copy of an email that I sent to nmusers in 1996 telling how to implement the Bayesian estimates using NM-TRAN.

-- Alison Boeckmann
=================
To: nmusers
Subject: Users Guide II

Here is an NM-TRAN control stream and a data file for the Bayesian regression example of Guide II Section C.

Please refer to that manual for a discussion.

Two things to note (from Stuart Beal):

(1) Use MAT=R when wanting SE's with single subject Bayesian regression.

(2) With single subject Bayesian regression, the SE is called the "standard deviation of the posterior variance", and not really an SE.

Alison Boeckmann

----
$PROBLEM BAYESIAN NONLIN REG OF CP VS TIME DATA FROM ONE SUBJECT - PREDPP
$INPUT DOSE=AMT TIME DV TYPE ID=L1
$INFI DATA.bayes
$SUBROUTINES ADVAN2 TRANS1
$THETAS (.4 1.7 7) (.025 .102 .4) (.3 3 30)
$OMEGA BLOCK(3) 5.55 .00524 .00024 -.128 .00911 .515 FIXED
$OMEGA BLOCK(1) .388 FIXED

$PK
KA=THETA(1)
K=THETA(2)
CL=THETA(3)
V=CL/K
S2=V

$ERROR
M0=0
M1=0
M2=0
M3=0
IF (TYPE.EQ.0) M0=1
IF (TYPE.EQ.1) M1=1
IF (TYPE.EQ.2) M2=1
IF (TYPE.EQ.3) M3=1
Y0=F+ERR(4) ; WHEN TYPE=0, TRUE VALUE OF CP
Y1=THETA(1)+ERR(1) ; WHEN TYPE=1, TRUE VALUE OF THETA(1)
Y2=THETA(2)+ERR(2) ; WHEN TYPE=2, TRUE VALUE OF THETA(2)
Y3=THETA(3)+ERR(3) ; WHEN TYPE=3, TRUE VALUE OF THETA(3)
Y=M0*Y0+M1*Y1+M2*Y2+M3*Y3

$ESTIMATION
$COVARIANCE MATRIX=R
$TABLE TYPE TIME
$SCAT (DV PRED RES) * TIME BY TYPE
$SCAT PRED VS DV BY TYPE UNIT
--------- DATA.bayes
320 0 0 0 0
0 0 2.77 1 0
0 0 .0781 2 0
0 0 2.63 3 0
0 .27 1.71 0 1
0 .52 7.91 0 2
0 1.0 8.31 0 3
0 1.92 8.33 0 4
0 3.5 6.85 0 5
0 5.02 6.08 0 6
0 7.03 5.4 0 7
0 9.0 4.55 0 8
0 12.0 3.01 0 9
0 24.3 .903 0 10
---------------
Results from the run:

THETA - VECTOR OF FIXED EFFECTS
2.12E+00 8.97E-02 3.02E+00
STANDARD ERROR OF ESTIMATE
THETA - VECTOR OF FIXED EFFECTS
2.81E-01 8.81E-03 2.34E-01