From: "Sreenivasa Rao Vanapalli" <rao@pharm.cpb.uokhsc.edu>
Subject: Weight as Covariate
Date: Fri, 22 Sep 2000 11:04:14 -0700

Dear NONMEM Users

I'm working on bioavailability studies on different intranasal formulations using population approach in rats. Since the dose is fixed and during the study the weight of the aniaml is geetting larger, We decided to include weight as predictor for Vd. The structural model is two compartment with first order absorption.

When we analyzed the data with NONMEM, We have two models: 1) without weight as covariate 2) with weight as covariate. I have obtained Bayesian individual estimates for parameters (Vd, K) using POSTHOC option with NONMEM. using this individual parameter estimates I have done exploratory data analysis for possible relationship between Vd and Weight. I found that there is a good relationship between Vd and weight. Interestingly when I include weight as covariate in my model minimum objective function (OBJ) decreased by 20 points. But the values of parameters changed so much that Ka and Vd values were decreased by a factor of 10 and K value was increased by a factor of 10. In other way it getting flip-flop. I am eager to know if anyone can explain this situation. (Is there anyway I can fix K value from prior knowledge). Here I'm attaching control files for both the models.

(with weight as covariate)
$PROBLEM PROMETHAZINE POOLED DATA
$INPUT ID DOSE=AMT TIME CP=DV WT PROD EVID
$DATA POOLEDATAWA
$SUBROUTINES ADVAN4

$PK
CALLFL=-1
KA1=THETA(1)
KA2=THETA(2)
KA3=THETA(3)
K23=THETA(6)*EXP(ETA(1))
K32=THETA(7)*EXP(ETA(2))
K=THETA(8)
TVVD=THETA(9)+THETA(10)*(WT-.3)
V=TVVD*EXP(ETA(3))
S2=V
KA=KA1
F1=1.0

IF (PROD.EQ.1) THEN
F1=THETA(4)
KA=KA2
ENDIF
IF (PROD.EQ.2) THEN
F1=THETA(5)
KA=KA3
ENDIF

$THETA (0,.15,10)(0,.4,10)(0,.35,10)(0,1.35,10)(0,1,10)
(0,.035,10)(0,.045,100)(0,.008,1)(0,.1,100)(0,.9,10)
$OMEGA .0001 .0001 .0001
$ERROR
Y=F*(1+ERR(1))+ERR(2)
$SIGMA .05 .001
$ESTIMATION MAXEVAL=9999
$COVARIANCE


(without weight as covariate)
$PROBLEM PROMETHAZINE POOLED DATA
$INPUT ID DOSE=AMT TIME CP=DV WT PROD EVID
$DATA POOLEDDATAW
$SUBROUTINES ADVAN4

$PK
CALLFL=-1
KA1=THETA(1)
KA2=THETA(2)
KA3=THETA(3)
K23=THETA(6)*EXP(ETA(1))
K32=THETA(7)*EXP(ETA(2))
K=THETA(8)
TVVD=THETA(9)
V=TVVD*EXP(ETA(3))
S2=V
KA=KA1
F1=1.0

IF (PROD.EQ.1) THEN
F1=THETA(4)
KA=KA2
ENDIF
IF (PROD.EQ.2) THEN
F1=THETA(5)
KA=KA3
ENDIF

$THETA (0,.15,10)(0,.4,10)(0,.35,10)(0,1.35,10)(0,1,10)
(0,.035,10)(0,.045,100)(0,.008,10)(0,.9,100)
$OMEGA .0001 .0001 .0001
$ERROR
Y=F*(1+ERR(1))+ERR(2)
$SIGMA .05 .001
$ESTIMATION MAXEVAL=9999
$COVARIANCE

A part of data file

1 500 0 0 0.35 0 1
1 . 2 149 .35 0 0
1 . 30.9 262 .35 0 0
1 . 119 163 .35 0 0
1 500 0 0 0.245 1 4
1 . 2 451 .245 1 0
1 . 30 328 .245 1 0
1 . 120 147 .245 1 0
1 500 0 0 0.295 2 4
1 . 2.1 346 .295 2 0
1 . 29.4 332.7 .295 2 0
1 . 119.4 178.1 .295 2 0


(without weight as covariate)
TH 1 TH 2 TH 3 TH 4 TH 5 TH 6 TH 7 TH 8
TH 9

1.54E-01 4.07E-01 3.76E-01 1.35E+00 1.04E+00 3.51E-02 4.15E-02
8.29E-03 1.02E+00

(with weight as covariate)
TH 1 TH 2 TH 3 TH 4 TH 5 TH 6 TH 7 TH 8
TH 9 TH10

3.39E-02 6.23E-02 6.28E-02 1.14E+00 9.34E-01 3.36E-01 3.20E-02
5.22E-02 1.33E-01 2.76E-01

With Regards
Sreenivasa Rao Vanapalli
College of Pharmacy,OUHSC
1110 N.Stonewall
Oklahoma City, OK-73117
Tel:405-271-6484 Extn:47232 (office)
:405-521-0826 (Home)
Fax:405-271-7505(Office)


*****


From: Nick Holford <n.holford@auckland.ac.nz>
Subject: Re: Weight as Covariate
Date: Sat, 23 Sep 2000 18:15:25 +1200

One obvious suggestion is to parameterize your model in terms of CL and V then use WT as a covariate on CL as well as V. It is theoretically absurd to imagine CL does not vary with WT. This may or may not fix your flip-flop problem but at least you will have a sensible description of CL and V.

Nick
--
Nick Holford, Dept Pharmacology & Clinical Pharmacology
University of Auckland, Private Bag 92019, Auckland, New Zealand
email:n.holford@auckland.ac.nz tel:+64(9)373-7599x6730 fax:373-7556
http://www.phm.auckland.ac.nz/Staff/NHolford/nholford.htm


*****


From: Lewis B Sheiner <lewis@c255.ucsf.edu>
Subject: Re: Weight as Covariate
Date: Sun, 24 Sep 2000 17:14:37 -0700

Regardint he flip-flop specifically, wouldn't one avoid it as usual: constrain KA >= K, e.g., with code such as

K=THETA(8)
KA1=THETA(1) + THETA(8)
KA2=THETA(2) + THETA(8)
KA3=THETA(3) + THETA(8)
...
Being sure, as in current code, that Theatas(1-3) are constrained >=0 ...

LBS.

--
_/ _/ _/_/ _/_/_/ _/_/_/ Lewis B Sheiner, MD (lewis@c255.ucsf.edu)
_/ _/ _/ _/_ _/_/ Professor: Lab. Med., Biophmct. Sci., Med.
_/ _/ _/ _/ _/ Box 0626, UCSF, SF, CA, 94143-0626
_/_/ _/_/ _/_/_/ _/ 415-476-1965 (v), 415-476-2796 (fax)